 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x+h/2 in dom cosec & x-h/2 in dom cosec implies
  cD(cosec(#)cosec,h).x = -4*sin(2*x)*sin(h)/(cos(2*x)-cos(h))^2
proof
  set f=cosec(#)cosec;
  assume
A1:x+h/2 in dom cosec & x-h/2 in dom cosec;
A2:sin.(x+h/2)<>0 & sin.(x-h/2)<>0 by A1,RFUNCT_1:3;
  x+h/2 in dom f & x-h/2 in dom f
  proof
    x+h/2 in dom cosec /\ dom cosec & x-h/2 in dom cosec /\ dom cosec by A1;
    hence thesis by VALUED_1:def 4;
  end; then
  cD(f,h).x = (cosec(#)cosec).(x+h/2)-(cosec(#)cosec).(x-h/2) by DIFF_1:39
    .= cosec.(x+h/2)*cosec.(x+h/2)-(cosec(#)cosec).(x-h/2) by VALUED_1:5
    .= cosec.(x+h/2)*cosec.(x+h/2)-cosec.(x-h/2)*cosec.(x-h/2) by VALUED_1:5
    .= (sin.(x+h/2))"*cosec.(x+h/2)-cosec.(x-h/2)*cosec.(x-h/2)
                                                      by A1,RFUNCT_1:def 2
    .= (sin.(x+h/2))"*(sin.(x+h/2))"-cosec.(x-h/2)*cosec.(x-h/2)
                                                      by A1,RFUNCT_1:def 2
    .= (sin.(x+h/2))"*(sin.(x+h/2))"-(sin.(x-h/2))"*cosec.(x-h/2)
                                                       by A1,RFUNCT_1:def 2
    .= ((sin.(x+h/2))")^2-((sin.(x-h/2))")^2 by A1,RFUNCT_1:def 2
    .= (1/sin.(x+h/2)-1/sin.(x-h/2))*(1/sin.(x+h/2)+1/sin.(x-h/2))
    .= ((1*sin.(x-h/2)-1*sin.(x+h/2))/(sin.(x+h/2)*sin.(x-h/2)))
       *(1/sin.(x+h/2)+1/sin.(x-h/2)) by A2,XCMPLX_1:130
    .= ((sin.(x-h/2)-sin.(x+h/2))/(sin.(x+h/2)*sin.(x-h/2)))
       *((sin.(x-h/2)+sin.(x+h/2))/(sin.(x+h/2)*sin.(x-h/2)))
                                                        by A2,XCMPLX_1:116
    .= ((sin.(x-h/2)-sin.(x+h/2))*(sin.(x-h/2)+sin.(x+h/2)))
       /((sin.(x+h/2)*sin.(x-h/2))*(sin.(x+h/2)*sin.(x-h/2))) by XCMPLX_1:76
    .= (sin(x-h/2)*sin(x-h/2)-sin(x+h/2)*sin(x+h/2))/(sin(x+h/2)*sin(x-h/2))^2
    .= (sin((x-h/2)+(x+h/2))*sin((x-h/2)-(x+h/2)))/(sin(x+h/2)*sin(x-h/2))^2
                                                                by SIN_COS4:37
    .= (sin(2*x)*sin(-h))
       /(-(1/2)*(cos((x+h/2)+(x-h/2))-cos((x+h/2)-(x-h/2))))^2 by SIN_COS4:29
    .= (sin(2*x)*(-sin(h)))/((1/4)*(cos(2*x)-cos(h))^2) by SIN_COS:31
    .= -1*(sin(2*x)*sin(h))/((1/4)*(cos(2*x)-cos(h))^2)
    .= -(1/(1/4))*((sin(2*x)*sin(h))/(cos(2*x)-cos(h))^2) by XCMPLX_1:76
    .= -4*sin(2*x)*sin(h)/(cos(2*x)-cos(h))^2;
  hence thesis;
end;
