 reserve o for object;
 reserve F for non almost_trivial Field;
 reserve x,a for Element of F;

theorem Th13:
  for x being non trivial Element of F, P being Ring
  st P = ExField(x,<%0.F,1.F%>) holds <%0.F,1.F%> in [#]P /\ [#]Polynom-Ring P
  proof
    let x be non trivial Element of F,P be Ring;
    set C = carr(x,<%0.F,1.F%>), E = ExField(x,<%0.F,1.F%>);
    assume
A1: P = E;
    <%0.F,1.F%> in {<%0.F,1.F%>} by TARSKI:def 1; then
    <%0.F,1.F%> in C by XBOOLE_0:def 3; then
A2: <%0.F,1.F%> in [#]E by Def8;
    now let n be Element of NAT;
      per cases by NAT_1:23;
       suppose
A3:      n = 0;
         hence <%0.F,1.F%>.n = 0.F by POLYNOM5:38  .= 0.E by Def8
         .= <%0.E,1.E%>.n by A3,POLYNOM5:38;
       end;
       suppose
A4:      n = 1;
         hence <%0.F,1.F%>.n = 1.F by POLYNOM5:38 .= 1.E by Def8
         .= <%0.E,1.E%>.n by A4,POLYNOM5:38;
       end;
       suppose
A5:      n >= 2;
         hence <%0.F,1.F%>.n = 0.F by POLYNOM5:38 .= 0.E by Def8
         .= <%0.E,1.E%>.n by A5,POLYNOM5:38;
       end;
     end; then
     <%0.F,1.F%> = <%0.E,1.E%>; then
     <%0.F,1.F%> in [#]Polynom-Ring P by A1,POLYNOM3:def 10;
     hence thesis by A1,A2,XBOOLE_0:def 4;
   end;
