
theorem
  for n being non zero Nat ex h being Function of FTSL2(n,1),
  FTSL1 n st h is being_homeomorphism
proof
  defpred P[object,object] means [$2,1]=$1;
  let n be non zero Nat;
  set FT1=FTSL2(n,1),FT2= FTSL1 n;
A1: for x be object st x in the carrier of FTSL2(n,1)
 ex y be object st y in the carrier of FTSL1 n & P[x,y]
  proof
    let x be object;
A2: FTSL1 n = RelStr(# Seg n,Nbdl1 n #) by FINTOPO4:def 4;
    assume x in the carrier of FTSL2(n,1);
    then consider u,v being object such that
A3: u in Seg n and
A4: v in Seg 1 and
A5: x= [u,v] by ZFMISC_1:def 2;
    reconsider nu=u,nv=v as Nat by A3,A4;
    1<=nv & nv<=1 by A4,FINSEQ_1:1;
    then P[x,nu] by A5,XXREAL_0:1;
    hence thesis by A3,A2;
  end;
  ex f being Function of FTSL2(n,1), FTSL1 n st
for x be object st x in the
  carrier of FTSL2(n,1) holds P[x,f.x] from FUNCT_2:sch 1(A1);
  then consider f being Function of FTSL2(n,1), FTSL1 n such that
A6: for x be object st x in the carrier of FTSL2(n,1) holds P[x,f.x];
A7: FTSL1 n = RelStr(# Seg n,Nbdl1 n #) by FINTOPO4:def 4;
A8: the carrier of FTSL1 n c= rng f
  proof
    let x be object;
    set z=[x,1];
A9: 1 in Seg 1;
    assume x in the carrier of FTSL1 n;
    then
A10: z in the carrier of FTSL2(n,1) by A7,A9,ZFMISC_1:def 2;
    then [f.z,1]=z by A6;
    then
A11: f.z=x by XTUPLE_0:1;
    z in dom f by A10,FUNCT_2:def 1;
    hence thesis by A11,FUNCT_1:def 3;
  end;
A12: for x being Element of FT1 holds f.:U_FT(x)=Im(the InternalRel of FT2,f
  .x)
  proof
    let x be Element of FT1;
    consider u,v being object such that
A13: u in Seg n and
A14: v in Seg 1 and
A15: x= [u,v] by ZFMISC_1:def 2;
A16: Im(the InternalRel of FT2,f.x) c= f.:U_FT x
    proof
      reconsider nv=v as Nat by A14;
      let y be object;
      assume
A17:  y in Im(the InternalRel of FT2,f.x);
      1 <= nv & nv <= 1 by A14,FINSEQ_1:1;
      then
A18:  nv = 1 by XXREAL_0:1;
      Im(Nbdl1 n,f.x) c= rng f by A7,A8;
      then consider x3 being object such that
A19:  x3 in dom f and
A20:  y=f.x3 by A7,A17,FUNCT_1:def 3;
      set u2=f.x3,v2=1;
      Im(Nbdl1 1,v) = {nv, max(nv-'1,1),min(nv+1,1)} by A14,FINTOPO4:def 3
        .= {1,max(0,1),min(2,1)} by A18,NAT_2:8
        .= {1,1,min(2,1)} by XXREAL_0:def 10
        .= {1, min(2,1)} by ENUMSET1:30
        .= {1, 1} by XXREAL_0:def 9
        .= {1} by ENUMSET1:29;
      then
A21:  v2 in Im(Nbdl1 1,v) by ZFMISC_1:31;
A22:  Im(Nbdl2(n,1),x) = [:Im(Nbdl1 n,u),Im(Nbdl1 1,v):] by A13,A14,A15,Def2;
      x=[f.x,1] by A6;
      then u2 in Im(Nbdl1 n,u) by A7,A15,A17,A20,XTUPLE_0:1;
      then
A23:  [u2,v2] in [:Im(Nbdl1 n,u),Im(Nbdl1 1,v):] by A21,ZFMISC_1:def 2;
      x3=[f.x3,1] by A6,A19;
      hence thesis by A19,A20,A23,A22,FUNCT_1:def 6;
    end;
    f.:U_FT x c= Im(the InternalRel of FT2,f.x)
    proof
      x=[f.x,1] by A6;
      then
A24:  u=f.x by A15,XTUPLE_0:1;
      let y be object;
      assume y in f.:U_FT x;
      then consider x2 being object such that
A25:  x2 in dom f and
A26:  x2 in Im(Nbdl2(n,1),x) & y=f.x2 by FUNCT_1:def 6;
A27:  Im(Nbdl2(n,1),x) =[:Im(Nbdl1 n,u),Im(Nbdl1 1,v):] by A13,A14,A15,Def2;
      x2=[f.x2,1] by A6,A25;
      hence thesis by A7,A26,A27,A24,ZFMISC_1:87;
    end;
    hence thesis by A16,XBOOLE_0:def 10;
  end;
  for x1,x2 being object st x1 in dom f & x2 in dom f & f.x1=f.x2 holds x1= x2
  proof
    let x1,x2 be object;
    assume that
A28: x1 in dom f and
A29: x2 in dom f & f.x1=f.x2;
    [f.x1,1]=x1 by A6,A28;
    hence thesis by A6,A29;
  end;
  then
A30: f is one-to-one by FUNCT_1:def 4;
  rng f= the carrier of FTSL1 n by A8,XBOOLE_0:def 10;
  then f is onto by FUNCT_2:def 3;
  then f is being_homeomorphism by A30,A12;
  hence thesis;
end;
