reserve x,y for object,
        D,D1,D2 for non empty set,
        i,j,k,m,n for Nat,
        f,g for FinSequence of D*,
        f1 for FinSequence of D1*,
        f2 for FinSequence of D2*;
reserve f for complex-valued Function,
        g,h for complex-valued FinSequence;

theorem Th13:
  k <= n implies
   (f,k) +...+ (f,n) = f.k + (f,k+1) +...+ (f,n)
proof
  set k1=k+1;
  assume A1:k <=n;
  per cases by A1,XXREAL_0:1;
  suppose A2:k =n;
    then A3:k+1 > n by NAT_1:13;
    thus (f,k) +...+ (f,n) = f.k +0 by A2,Th11
                          .= f.k + (f,k+1) +...+ (f,n) by A3,Def1;
  end;
  suppose A4: k < n;
    then k1 <= n by NAT_1:13;
    then consider h be complex-valued FinSequence such that
    A5:(f,k1) +...+ (f,n) = Sum h & len h = n-'k1+1 and
    A6: h.(0+1) = f.(0+k1) & ... & h.(n-'k1+1) = f.(n-'k1+k1) by Th9;
    reconsider fk=f.k as Complex;
    set h1 = <*fk*>^h;
    A7: n-'k1+1 = n-'k by A4,NAT_D:59;
    A8:len <*fk*> = 1 by FINSEQ_1:39;
    then len h1 = n-'k+1 by FINSEQ_1:22,A7,A5;
    then A9: h1| (n-'k+1) = h1 by FINSEQ_1:58;
    h1.(0+1) = f.(0+k) & ... & h1.(n-'k+1) = f.(n-'k+k)
    proof
      let i;
      set i1=i+1;
      assume A10: 0 <= i & i <= n-'k;
      per cases;
      suppose i=0;
        hence thesis by FINSEQ_1:41;
      end;
      suppose A11:i>0;
        then reconsider ii=i-1 as Nat;
        ii+1 <= n-'k1+1 by A4,NAT_D:59,A10;
        then ii <= n-'k1 by XREAL_1:6;
        then A12: h.(ii+1) = f.(ii+k1) by A6;
        i >= 1 by NAT_1:14,A11;
        then i in dom h by A5,A7,A10,FINSEQ_3:25;
        hence thesis by A8,FINSEQ_1:def 7,A12;
      end;
    end;
    hence (f,k) +...+ (f,n) = Sum h1 by Def1,A4,A9
                           .= f.k +(f,k+1) +...+ (f,n) by RVSUM_2:33,A5;
  end;
end;
