
theorem Th13:
  the carrier of F_Rat is Subset of the carrier of F_Real
  & the addF of F_Rat = (the addF of F_Real) || (the carrier of F_Rat)
  & the multF of F_Rat = (the multF of F_Real) || (the carrier of F_Rat)
  & 1.F_Rat = 1.F_Real & 0.F_Rat = 0.F_Real
  & F_Rat is right_complementable commutative almost_left_invertible
  non degenerated
  proof
    A1: for v being Element of F_Rat holds v is right_complementable
    proof
      let v be Element of F_Rat;
      reconsider v1 = v as Rational;
      set w1 = -v1;
      reconsider w = w1 as Element of F_Rat by RAT_1:def 2;
      v + w = v1+w1 by BINOP_2:def 15
      .= 0.F_Rat;
      hence v is right_complementable;
    end;
    A2:
    now let x, y be Element of F_Rat;
      reconsider x1 = x, y1 = y as Rational;
      thus x*y = x1*y1 by BINOP_2:def 17
      .= y*x by BINOP_2:def 17;
    end;
    for v being Element of F_Rat st v <> 0. F_Rat
    holds v is left_invertible
    proof
      let v be Element of F_Rat;
      assume A3: v <> 0. F_Rat;
      reconsider v1 = v as Rational;
      set w1 = v1";
      reconsider w = w1 as Element of F_Rat by RAT_1:def 2;
      w * v = w1*v1 by BINOP_2:def 17
      .= 1.F_Rat by A3,XCMPLX_0:def 7;
      hence v is left_invertible;
    end;
    hence thesis by A1,A2,Lm6,Lm7,GROUP_1:def 12,NUMBERS:12;
  end;
