
theorem Th13:
  for G1, G2 being _Graph, F being PGraphMapping of G1, G2
  holds F is directed iff
    for e being object st e in dom F_E
    holds (the_Source_of G2).(F_E.e) = F_V.((the_Source_of G1).e) &
      (the_Target_of G2).(F_E.e) = F_V.((the_Target_of G1).e)
proof
  let G1, G2 be _Graph, F be PGraphMapping of G1, G2;
  thus F is directed implies
    for e being object st e in dom F_E
    holds (the_Source_of G2).(F_E.e) = F_V.((the_Source_of G1).e) &
      (the_Target_of G2).(F_E.e) = F_V.((the_Target_of G1).e)
  proof
    assume A1: F is directed;
    let e be object;
    assume A2: e in dom F_E;
    then A3: (the_Source_of G1).e in dom F_V & (the_Target_of G1).e in dom F_V
      by Th5;
    e DJoins (the_Source_of G1).e, (the_Target_of G1).e, G1
      by A2, GLIB_000:def 14;
    then F_E.e DJoins F_V.((the_Source_of G1).e), F_V.((the_Target_of G1).e),
      G2 by A1, A2, A3;
    hence thesis by GLIB_000:def 14;
  end;
  assume A4: for e being object st e in dom F_E
    holds (the_Source_of G2).(F_E.e) = F_V.((the_Source_of G1).e) &
      (the_Target_of G2).(F_E.e) = F_V.((the_Target_of G1).e);
  let e,v,w be object;
  assume A5: e in dom F_E & v in dom F_V & w in dom F_V;
  assume e DJoins v,w,G1;
  then A6: (the_Source_of G1).e = v & (the_Target_of G1).e = w
    by GLIB_000:def 14;
  (the_Source_of G2).(F_E.e) = F_V.v & (the_Target_of G2).(F_E.e) = F_V.w
    by A4, A5, A6;
  hence thesis by A5, PARTFUN1:4, GLIB_000:def 14;
end;
