reserve f for non empty FinSequence of TOP-REAL 2,
  i,j,k,k1,k2,n,i1,i2,j1,j2 for Nat,
  r,s,r1,r2 for Real,
  p,q,p1,q1 for Point of TOP-REAL 2,
  G for Go-board;

theorem Th13:
  1 <= i & i <= len G & 1 <= j & j+2 <= width G implies LSeg(G*(i,
  j),G*(i,j+1)) /\ LSeg(G*(i,j+1),G*(i,j+2)) = { G*(i,j+1) }
proof
  assume that
A1: 1 <= i & i <= len G and
A2: 1 <= j and
A3: j+2 <= width G;
  now
    let x be object;
    hereby
      assume
A4:   x in LSeg(G*(i,j),G*(i,j+1)) /\ LSeg(G*(i,j+1),G*(i,j+2));
      then reconsider p = x as Point of TOP-REAL 2;
A5:   x in LSeg(G*(i,j),G*(i,j+1)) by A4,XBOOLE_0:def 4;
A6:   p in LSeg(G*(i,j+1),G*(i,j+2)) by A4,XBOOLE_0:def 4;
      j <= j+2 by NAT_1:11;
      then
A7:   j <= width G by A3,XXREAL_0:2;
A8:   j+1 < j+2 by XREAL_1:6;
      then
A9:   j+1 <= width G by A3,XXREAL_0:2;
A10:  1 <= j+1 by NAT_1:11;
      then G*(i,j+1)`1 = G*(i,1)`1 by A1,A9,GOBOARD5:2
        .= G*(i,j)`1 by A1,A2,A7,GOBOARD5:2;
      then
A11:  p`1 = G*(i,j+1)`1 by A5,Th5;
      j < j+1 by XREAL_1:29;
      then G*(i,j)`2 < G*(i,j+1)`2 by A1,A2,A9,GOBOARD5:4;
      then
A12:  p`2 <= G*(i,j+1)`2 by A5,TOPREAL1:4;
      G*(i,j+1)`2 < G*(i,j+2)`2 by A1,A3,A8,A10,GOBOARD5:4;
      then p`2 >= G*(i,j+1)`2 by A6,TOPREAL1:4;
      then p`2 = G*(i,j+1)`2 by A12,XXREAL_0:1;
      hence x = G*(i,j+1) by A11,TOPREAL3:6;
    end;
    assume x = G*(i,j+1);
    then x in LSeg(G*(i,j),G*(i,j+1)) & x in LSeg(G*(i,j+1),G*(i,j+2)) by
RLTOPSP1:68;
    hence x in LSeg(G*(i,j),G*(i,j+1)) /\ LSeg(G*(i,j+1),G*(i,j+2)) by
XBOOLE_0:def 4;
  end;
  hence thesis by TARSKI:def 1;
end;
