reserve f for non constant standard special_circular_sequence,
  i,j,k,i1,i2,j1,j2 for Nat,
  r,s,r1,s1,r2,s2 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board;

theorem Th12:
  i <= len G implies Int v_strip(G,i) is convex
proof
  assume
A1: i <= len G;
  per cases by A1,NAT_1:14,XXREAL_0:1;
  suppose i = 0;
    then Int v_strip(G,i) = { |[r,s]| : r < G*(1,1)`1 } by GOBOARD6:12;
    hence thesis by JORDAN1:13;
  end;
  suppose i = len G;
    then Int v_strip(G,i) = { |[r,s]| : G*(len G,1)`1 < r } by GOBOARD6:13;
    hence thesis by JORDAN1:11;
  end;
  suppose 1 <= i & i < len G;
    then
A2: Int v_strip(G,i) = { |[r,s]| : G*(i,1)`1 < r & r < G*(i+1,1)`1 }
    by GOBOARD6:14;
A3: { |[r,s]| : G*(i,1)`1 < r} c= the carrier of TOP-REAL 2
    proof
      let x be object;
      assume x in { |[r,s]| : G*(i,1)`1 < r};
      then ex r,s st x = |[r,s]| & G*(i,1)`1 < r;
      hence thesis;
    end;
    { |[r,s]| : r < G*(i+1,1)`1 } c= the carrier of TOP-REAL 2
    proof
      let x be object;
      assume x in { |[r,s]| : r < G*(i+1,1)`1 };
      then ex r,s st x = |[r,s]| & r < G*(i+1,1)`1;
      hence thesis;
    end;
    then reconsider P = { |[r,s]| : G*(i,1)`1 < r},
    Q = { |[r,s]| : r < G*(i+1,1)`1 } as Subset of TOP-REAL 2 by A3;
A4: Int v_strip(G,i) = P /\ Q
    proof
      hereby
        let x be object;
        assume x in Int v_strip(G,i);
        then
A5:     ex r,s st x = |[r,s]| & G*(i,1)`1 < r & r < G*(i+1,1)`1 by A2;
        then
A6:     x in P;
        x in Q by A5;
        hence x in P /\ Q by A6,XBOOLE_0:def 4;
      end;
      let x be object;
      assume
A7:   x in P /\ Q;
      then x in P by XBOOLE_0:def 4;
      then consider r1,s1 such that
A8:   x = |[r1,s1]| and
A9:   G*(i,1)`1 < r1;
      x in Q by A7,XBOOLE_0:def 4;
      then consider r2,s2 such that
A10:  x = |[r2,s2]| and
A11:  r2 < G*(i+1,1)`1;
      r1 = r2 by A8,A10,SPPOL_2:1;
      hence thesis by A2,A8,A9,A11;
    end;
A12: P is convex by JORDAN1:11;
    Q is convex by JORDAN1:13;
    hence thesis by A4,A12,Th5;
  end;
end;
