reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;

theorem
  for A1, A2 being Subset of TOP-REAL 2 st (L~f)` = A1 \/ A2 & A1 misses
A2 & for C1, C2 being Subset of (TOP-REAL 2)|(L~f)` st C1 = A1 & C2 = A2 holds
C1 is a_component & C2 is a_component
holds A1 = RightComp f & A2 = LeftComp f or A1 = LeftComp f & A2 =
  RightComp f
proof
  let A1, A2 be Subset of TOP-REAL 2 such that
A1: (L~f)` = A1 \/ A2 and
A2: A1 /\ A2 = {} and
A3: for C1, C2 being Subset of (TOP-REAL 2)|(L~f)` st C1 = A1 & C2 = A2
holds C1 is a_component & C2 is a_component;
  the carrier of (TOP-REAL 2)|(L~f)` = (L~f)` by PRE_TOPC:8;
  then reconsider C1 = A1, C2 = A2 as Subset of (TOP-REAL 2)|(L~f)` by A1,
XBOOLE_1:7;
  C1 = A1;
  then C2 is a_component by A3;
  then
A4: C2 = RightComp f or C2 = LeftComp f by Th12;
  C2 = A2;
  then C1 is a_component by A3;
  then
A5: C1 = RightComp f or C1 = LeftComp f by Th12;
  assume not thesis;
  hence contradiction by A2,A5,A4;
end;
