 reserve a,x for Real;
 reserve n for Nat;
 reserve A for non empty closed_interval Subset of REAL;
 reserve f,f1 for PartFunc of REAL,REAL;
 reserve Z for open Subset of REAL;

theorem Th13:
  Z c= dom (cot(#)cosec) implies (-cot(#)cosec) is_differentiable_on Z &
  for x st x in Z holds
  ((-cot(#)cosec)`|Z).x = 1/(sin.x)^2/sin.x+cot.x*cos.x/(sin.x)^2
proof
   assume
A1:Z c= dom (cot(#)cosec);
then A2:Z c= dom (-cot(#)cosec) by VALUED_1:8;
A3:(cot(#)cosec) is_differentiable_on Z by A1,FDIFF_9:45;
then A4:(-1)(#)(cot(#)cosec) is_differentiable_on Z by A2,FDIFF_1:20;
 for x st x in Z holds
   ((-cot(#)cosec)`|Z).x = 1/(sin.x)^2/sin.x+cot.x*cos.x/(sin.x)^2
   proof
      let x;
      assume
A5:x in Z;
  ((-cot(#)cosec)`|Z).x = ((-1)(#)((cot(#)cosec)`|Z)).x by A3,FDIFF_2:19
   .=(-1)*(((cot(#)cosec)`|Z).x) by VALUED_1:6
   .=(-1)*(-1/(sin.x)^2/sin.x-cot.x*cos.x/(sin.x)^2) by A1,A5,FDIFF_9:45
   .=1/(sin.x)^2/sin.x+cot.x*cos.x/(sin.x)^2;
     hence thesis;
   end;
   hence thesis by A4;
end;
