reserve i,k,n,m for Element of NAT;
reserve a,b,r,r1,r2,s,x,x1,x2 for Real;
reserve A for non empty closed_interval Subset of REAL;
reserve X for set;

theorem Th13:
  for f being PartFunc of REAL,REAL st A c= X & f
  is_differentiable_on X & f`|X is_integrable_on A & (f`|X)|A is bounded holds
  integral(f`|X,A) = f.(upper_bound A)-f.(lower_bound A)
proof
  let f be PartFunc of REAL,REAL;
  assume that
A1: A c= X & f is_differentiable_on X and
A2: f`|X is_integrable_on A and
A3: (f`|X)|A is bounded;
  (f`|X)||A is integrable by A2;
  then
A4: upper_integral((f`|X)||A)=lower_integral((f`|X)||A) by INTEGRA1:def 16;
A5: for r be Real st r in rng upper_sum_set((f`|X)||A)
holds f.(upper_bound
  A)-f.(lower_bound A) <= r
  proof
    let r be Real;
    assume r in rng upper_sum_set((f`|X)||A);
    then consider D being Element of divs A such that
A6: D in dom upper_sum_set((f`|X)||A) & r=(upper_sum_set((f`|X)||A)).
    D by PARTFUN1:3;
    reconsider D as Division of A by INTEGRA1:def 3;
    r=upper_sum((f`|X)||A,D) by A6,INTEGRA1:def 10;
    hence thesis by A1,A3,Th12;
  end;
  f.(upper_bound A)-f.(lower_bound A) <=
  lower_bound rng upper_sum_set((f`|X)||A) by A5,SEQ_4:43;
  then
A7: upper_integral((f`|X)||A) >= f.(upper_bound A)-f.(lower_bound A)
by INTEGRA1:def 14;
A8: for r be Real st r in rng lower_sum_set((f`|X)||A) holds r <= f.
  (upper_bound A)-f.(lower_bound A)
  proof
    let r be Real;
    assume r in rng lower_sum_set((f`|X)||A);
    then consider D being Element of divs A such that
A9: D in dom lower_sum_set((f`|X)||A) & r=(lower_sum_set((f`|X)||A)).
    D by PARTFUN1:3;
    reconsider D as Division of A by INTEGRA1:def 3;
    r=lower_sum((f`|X)||A,D) by A9,INTEGRA1:def 11;
    hence thesis by A1,A3,Th12;
  end;
  upper_bound rng lower_sum_set((f`|X)||A) <=
   f.(upper_bound A)-f.(lower_bound A) by A8,SEQ_4:45;
  then upper_integral((f`|X)||A) <=
   f.(upper_bound A)-f.(lower_bound A) by A4,INTEGRA1:def 15;
  then upper_integral((f`|X)||A) =
   f.(upper_bound A)-f.(lower_bound A) by A7,XXREAL_0:1;
  hence thesis by INTEGRA1:def 17;
end;
