reserve x,y for set;
reserve G for Graph;
reserve vs,vs9 for FinSequence of the carrier of G;
reserve IT for oriented Chain of G;
reserve N for Nat;
reserve n,m,k,i,j for Nat;
reserve r,r1,r2 for Real;
reserve X for non empty set;

theorem Th13:
  for f being FinSequence of TOP-REAL 2 st f is s.c.c. & LSeg(f,1)
  misses LSeg(f,len f -'1) holds f is s.n.c.
proof
  let f be FinSequence of TOP-REAL 2;
  assume that
A1: f is s.c.c. and
A2: LSeg(f,1) misses LSeg(f,len f -'1);
  for i,j be Nat st i+1 < j holds LSeg(f,i) misses LSeg(f,j)
  proof
    let i,j be Nat;
    assume
A3: i+1 < j;
    per cases;
    suppose
      len f<>0;
      then
A4:   len f>=0 qua Nat+1 by NAT_1:13;
      now
        per cases;
        case
A5:       1<=i & j+1<=len f;
          then
A6:       j<len f by NAT_1:13;
          now
            per cases;
            case
A7:           i=1 & j+1=len f;
              then j=len f-1;
              then LSeg(f,i) misses LSeg(f,j) by A2,A4,A7,XREAL_1:233;
              hence LSeg(f,i) /\ LSeg(f,j) = {};
            end;
            case
              not(i=1 & j+1=len f);
              then i>1 or j+1<len f by A5,XXREAL_0:1;
              then LSeg(f,i) misses LSeg(f,j) by A1,A3,A6,GOBOARD5:def 4;
              hence LSeg(f,i) /\ LSeg(f,j) = {};
            end;
          end;
          hence LSeg(f,i) /\ LSeg(f,j) = {};
        end;
        case
A8:       not (1<=i & j+1<=len f);
          now
            per cases by A8;
            case
              1>i;
              then LSeg(f,i)={} by TOPREAL1:def 3;
              hence LSeg(f,i) /\ LSeg(f,j) = {};
            end;
            case
              j+1>len f;
              then LSeg(f,j)={} by TOPREAL1:def 3;
              hence LSeg(f,i) /\ LSeg(f,j) = {};
            end;
          end;
          hence LSeg(f,i) /\ LSeg(f,j) = {};
        end;
      end;
      hence thesis;
    end;
    suppose
A9:  len f=0;
      now
        per cases;
        case
          i>=1;
          i+1>len f by A9;
          then LSeg(f,i)={} by TOPREAL1:def 3;
          hence LSeg(f,i) /\ LSeg(f,j) = {};
        end;
        case
          i<1;
          then LSeg(f,i)={} by TOPREAL1:def 3;
          hence LSeg(f,i) /\ LSeg(f,j) = {};
        end;
      end;
      hence thesis;
    end;
  end;
  hence thesis by TOPREAL1:def 7;
end;
