reserve i, j, k, n for Nat,
  P for Subset of TOP-REAL 2,
  C for connected compact non vertical non horizontal Subset of TOP-REAL 2;

theorem Th13:
  UBD L~Cage(C,n) c= UBD C
proof
  set f = Cage(C,n);
A1: UBD C = union {B where B is Subset of TOP-REAL 2: B
  is_outside_component_of C} by JORDAN2C:def 5;
  let x be object;
A2: UBD L~f = union {B where B is Subset of TOP-REAL 2: B
  is_outside_component_of L~f} by JORDAN2C:def 5;
  assume x in UBD L~f;
  then consider L being set such that
A3: x in L and
A4: L in {B where B is Subset of TOP-REAL 2: B is_outside_component_of
  L~f} by A2,TARSKI:def 4;
  consider B being Subset of TOP-REAL 2 such that
A5: L = B and
A6: B is_outside_component_of L~f by A4;
  reconsider B1 = B as Subset of Euclid 2 by TOPREAL3:8;
A7: B1 misses RightComp f by A6,GOBRD14:35,JORDAN2C:118;
  then
A8: B1 /\ RightComp f = {};
  the carrier of (TOP-REAL 2)|C` = C` by PRE_TOPC:8;
  then reconsider P1 = Component_of (Down(B,C`)) as Subset of TOP-REAL 2 by
XBOOLE_1:1;
  B is_a_component_of (L~f)` by A6,JORDAN2C:def 3;
  then consider B2 being Subset of (TOP-REAL 2)|(L~f)` such that
A9: B2 = B and
A10: B2 is a_component by CONNSP_1:def 6;
  B2 is connected by A10,CONNSP_1:def 5;
  then
A11: B is connected by A9,CONNSP_1:23;
A12: C c= RightComp f by Th11;
  then not x in C by A3,A5,A8,XBOOLE_0:def 4;
  then x in C` by A3,A5,XBOOLE_0:def 5;
  then
A13: x in B /\ C` by A3,A5,XBOOLE_0:def 4;
  not B is bounded by A6,JORDAN2C:def 3;
  then
A14: not B1 is bounded by JORDAN2C:11;
  B1 misses C by A7,Th11,XBOOLE_1:63;
  then P1 is_outside_component_of C by A11,A14,JORDAN2C:63;
  then
A15: P1 in {W where W is Subset of TOP-REAL 2: W is_outside_component_of C };
  B c= C`
  proof
    let a be object;
    assume
A16: a in B;
    then not a in C by A12,A8,XBOOLE_0:def 4;
    hence thesis by A16,XBOOLE_0:def 5;
  end;
  then Down(B,C`) = B by XBOOLE_1:28;
  then Down(B,C`) c= Component_of Down(B,C`) by A11,CONNSP_1:46,CONNSP_3:1;
  hence thesis by A1,A13,A15,TARSKI:def 4;
end;
