reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;
reserve f,g for FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence,
  p,p1,p2,q for Point of TOP-REAL 2;

theorem Th13:
  for f,p1,p2 st LSeg(p1,p2) misses L~f holds ex C be Subset of
  TOP-REAL 2 st C is_a_component_of (L~f)` & p1 in C & p2 in C
proof
  let f,p1,p2;
  assume
A1: LSeg(p1,p2) misses L~f;
A2: RightComp f is_a_component_of (L~f)` by GOBOARD9:def 2;
A3: p1 in LSeg(p1,p2) by RLTOPSP1:68;
  then
A4: not p1 in L~f by A1,XBOOLE_0:3;
A5: p2 in LSeg(p1,p2) by RLTOPSP1:68;
  then
A6: not p2 in L~f by A1,XBOOLE_0:3;
A7: not (p2 in RightComp f & p1 in LeftComp f) by A1,A3,A5,JORDAN1J:36;
A8: LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
  now
    per cases by A1,A3,A5,JORDAN1J:36;
    suppose
      not p1 in RightComp f;
      then p1 in LeftComp f & p2 in LeftComp f by A7,A4,A6,GOBRD14:17;
      hence thesis by A8;
    end;
    suppose
      not p2 in LeftComp f;
      then p2 in RightComp f & p1 in RightComp f by A7,A4,A6,GOBRD14:18;
      hence thesis by A2;
    end;
  end;
  hence thesis;
end;
