reserve n for Nat;

theorem Th13:
  for C be Simple_closed_curve for i,j,k be Nat st
  1 < i & i < len Gauge(C,n) & 1 <= k & k <= j & j <= width Gauge(C,n) &
  LSeg(Gauge(C,n)*(i,k),Gauge(C,n)*(i,j)) /\ L~Upper_Seq(C,n) =
  {Gauge(C,n)*(i,k)} &
  LSeg(Gauge(C,n)*(i,k),Gauge(C,n)*(i,j)) /\ L~Lower_Seq(C,n) =
  {Gauge(C,n)*(i,j)} holds
  LSeg(Gauge(C,n)*(i,k),Gauge(C,n)*(i,j)) meets Lower_Arc C
proof
  let C be Simple_closed_curve;
  let i,j,k be Nat;
  set Ga = Gauge(C,n);
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  set LA = Lower_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gik = Ga*(i,k);
  set Gij = Ga*(i,j);
  assume that
A1: 1 < i and
A2: i < len Ga and
A3: 1 <= k and
A4: k <= j and
A5: j <= width Ga and
A6: LSeg(Gik,Gij) /\ L~US = {Gik} and
A7: LSeg(Gik,Gij) /\ L~LS = {Gij} and
A8: LSeg(Gik,Gij) misses LA;
  Gij in {Gij} by TARSKI:def 1;
  then
A9: Gij in L~LS by A7,XBOOLE_0:def 4;
  Gik in {Gik} by TARSKI:def 1;
  then
A10: Gik in L~US by A6,XBOOLE_0:def 4;
  then
A11: j <> k by A1,A2,A3,A5,A9,JORDAN1J:57;
A12: 1 <= j by A3,A4,XXREAL_0:2;
A13: k <= width Ga by A4,A5,XXREAL_0:2;
A14: [i,j] in Indices Ga by A1,A2,A5,A12,MATRIX_0:30;
A15: [i,k] in Indices Ga by A1,A2,A3,A13,MATRIX_0:30;
  set co = L_Cut(LS,Gij);
  set go = R_Cut(US,Gik);
A16: len Ga = width Ga by JORDAN8:def 1;
A17: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A18: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A19: Wmin`1 = Wbo
    .= Ga*(1,k)`1 by A3,A13,A16,JORDAN1A:73;
  len Ga >= 4 by JORDAN8:10;
  then
A20: len Ga >= 1 by XXREAL_0:2;
  then
A21: [1,k] in Indices Ga by A3,A13,MATRIX_0:30;
  then
A22: Gik <> US.1 by A1,A15,A18,A19,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2
  by A10,JORDAN3:35;
A23: len LS >= 1+2 by JORDAN1E:15;
  then
A24: len LS >= 1 by XXREAL_0:2;
  then
A25: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A24,FINSEQ_3:25;
  then
A26: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
A27: Wmin`1 = Wbo
    .= Ga*(1,k)`1 by A3,A13,A16,JORDAN1A:73;
A28: [i,j] in Indices Ga by A1,A2,A5,A12,MATRIX_0:30;
  then
A29: Gij <> LS.len LS by A1,A21,A26,A27,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2
  by A9,JORDAN3:34;
A30: [len Ga,k] in Indices Ga by A3,A13,A20,MATRIX_0:30;
A31: LS.1 = LS/.1 by A25,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo
    .= Ga*(len Ga,k)`1 by A3,A13,A16,JORDAN1A:71;
  then
A32: Gij <> LS.1 by A2,A28,A30,A31,JORDAN1G:7;
A33: len go >= 1+1 by TOPREAL1:def 8;
A34: Gik in rng US by A1,A2,A3,A10,A13,JORDAN1G:4,JORDAN1J:40;
  then
A35: go is_sequence_on Ga by JORDAN1G:4,JORDAN1J:38;
A36: len co >= 1+1 by TOPREAL1:def 8;
A37: Gij in rng LS by A1,A2,A5,A9,A12,JORDAN1G:5,JORDAN1J:40;
  then
A38: co is_sequence_on Ga by JORDAN1G:5,JORDAN1J:39;
  reconsider go as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A33,A35,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c.
  being_S-Seq FinSequence of TOP-REAL 2 by A36,A38,JGRAPH_1:12,JORDAN8:5;
A39: len go > 1 by A33,NAT_1:13;
  then
A40: len go in dom go by FINSEQ_3:25;
  then
A41: go/.len go = go.len go by PARTFUN1:def 6
    .= Gik by A10,JORDAN3:24;
  len co >= 1 by A36,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A42: co/.1 = co.1 by PARTFUN1:def 6
    .= Gij by A9,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A40,FINSEQ_3:26;
A43: m+1 = len go;
  then
A44: len go-'1 = m by NAT_D:34;
A45: LSeg(go,m) c= L~go by TOPREAL3:19;
A46: L~go c= L~US by A10,JORDAN3:41;
  then LSeg(go,m) c= L~US by A45;
  then
A47: LSeg(go,m) /\ LSeg(Gik,Gij) c= {Gik} by A6,XBOOLE_1:26;
  m >= 1 by A33,XREAL_1:19;
  then
A48: LSeg(go,m) = LSeg(go/.m,Gik) by A41,A43,TOPREAL1:def 3;
  {Gik} c= LSeg(go,m) /\ LSeg(Gik,Gij)
  proof
    let x be object;
    assume x in {Gik};
    then
A49: x = Gik by TARSKI:def 1;
A50: Gik in LSeg(go,m) by A48,RLTOPSP1:68;
    Gik in LSeg(Gik,Gij) by RLTOPSP1:68;
    hence thesis by A49,A50,XBOOLE_0:def 4;
  end;
  then
A51: LSeg(go,m) /\ LSeg(Gik,Gij) = {Gik} by A47;
A52: LSeg(co,1) c= L~co by TOPREAL3:19;
A53: L~co c= L~LS by A9,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A52;
  then
A54: LSeg(co,1) /\ LSeg(Gik,Gij) c= {Gij} by A7,XBOOLE_1:26;
A55: LSeg(co,1) = LSeg(Gij,co/.(1+1)) by A36,A42,TOPREAL1:def 3;
  {Gij} c= LSeg(co,1) /\ LSeg(Gik,Gij)
  proof
    let x be object;
    assume x in {Gij};
    then
A56: x = Gij by TARSKI:def 1;
A57: Gij in LSeg(co,1) by A55,RLTOPSP1:68;
    Gij in LSeg(Gik,Gij) by RLTOPSP1:68;
    hence thesis by A56,A57,XBOOLE_0:def 4;
  end;
  then
A58: LSeg(Gik,Gij) /\ LSeg(co,1) = {Gij} by A54;
A59: go/.1 = US/.1 by A10,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A60: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A9,JORDAN1J:35;
A61: rng go c= L~go by A33,SPPOL_2:18;
A62: rng co c= L~co by A36,SPPOL_2:18;
A63: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A64: x = go/.1 by TARSKI:def 1;
    then
A65: x in rng go by FINSEQ_6:42;
    x in rng co by A60,A64,FINSEQ_6:168;
    hence thesis by A61,A62,A65,XBOOLE_0:def 4;
  end;
A66: LS.1 = LS/.1 by A25,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A67: [len Ga,j] in Indices Ga by A5,A12,A20,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A68: x in L~go /\ L~co;
    then
A69: x in L~go by XBOOLE_0:def 4;
A70: x in L~co by A68,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A46,A53,A69,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then
A71: x = Wmin or x = Emax by TARSKI:def 2;
    now
      assume x = Emax;
      then
A72:  Emax = Gij by A9,A66,A70,JORDAN1E:7;
      Ga*(len Ga,j)`1 = Ebo by A5,A12,A16,JORDAN1A:71;
      then Emax`1 <> Ebo by A2,A14,A67,A72,JORDAN1G:7;
      hence contradiction;
    end;
    hence thesis by A59,A71,TARSKI:def 1;
  end;
  then
A73: L~go /\ L~co = {go/.1} by A63;
  set W2 = go/.2;
A74: 2 in dom go by A33,FINSEQ_3:25;
A75: now
    assume Gik`1 = Wbo;
    then Ga*(1,k)`1 = Ga*(i,k)`1 by A3,A13,A16,JORDAN1A:73;
    hence contradiction by A1,A15,A21,JORDAN1G:7;
  end;
  go = mid(US,1,Gik..US) by A34,JORDAN1G:49
    .= US|(Gik..US) by A34,FINSEQ_4:21,FINSEQ_6:116;
  then
A76: W2 = US/.2 by A74,FINSEQ_4:70;
A77: Wmin in rng go by A59,FINSEQ_6:42;
  set pion = <*Gik,Gij*>;
A78: now
    let n be Nat;
    assume n in dom pion;
    then n in Seg 2 by FINSEQ_1:89;
    then n = 1 or n = 2 by FINSEQ_1:2,TARSKI:def 2;
    hence
    ex i,j be Nat st [i,j] in Indices Ga & pion/.n = Ga*(i,j)
    by A14,A15,FINSEQ_4:17;
  end;
A79: Gik <> Gij by A11,A14,A15,GOBOARD1:5;
A80: Gik`1 = Ga*(i,1)`1 by A1,A2,A3,A13,GOBOARD5:2
    .= Gij`1 by A1,A2,A5,A12,GOBOARD5:2;
  then LSeg(Gik,Gij) is vertical by SPPOL_1:16;
  then pion is being_S-Seq by A79,JORDAN1B:7;
  then consider pion1 be FinSequence of TOP-REAL 2 such that
A81: pion1 is_sequence_on Ga and
A82: pion1 is being_S-Seq and
A83: L~pion = L~pion1 and
A84: pion/.1 = pion1/.1 and
A85: pion/.len pion = pion1/.len pion1 and
A86: len pion <= len pion1 by A78,GOBOARD3:2;
  reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A82;
  set godo = go^'pion1^'co;
A87: 1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A88: 1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
  len (go^'pion1) >= len go by TOPREAL8:7;
  then
A89: len (go^'pion1) >= 1+1 by A33,XXREAL_0:2;
  then
A90: len (go^'pion1) > 1+0 by NAT_1:13;
A91: len godo >= len (go^'pion1) by TOPREAL8:7;
  then
A92: 1+1 <= len godo by A89,XXREAL_0:2;
A93: US is_sequence_on Ga by JORDAN1G:4;
A94: go/.len go = pion1/.1 by A41,A84,FINSEQ_4:17;
  then
A95: go^'pion1 is_sequence_on Ga by A35,A81,TOPREAL8:12;
A96: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A85,FINSEQ_6:156
    .= pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
  then
A97: godo is_sequence_on Ga by A38,A95,TOPREAL8:12;
  LSeg(pion1,1) c= L~<*Gik,Gij*> by A83,TOPREAL3:19;
  then LSeg(pion1,1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A98: LSeg(go,len go-'1) /\ LSeg(pion1,1) c= {Gik} by A44,A51,XBOOLE_1:27;
A99: len pion1 >= 1+1 by A86,FINSEQ_1:44;
  {Gik} c= LSeg(go,m) /\ LSeg(pion1,1)
  proof
    let x be object;
    assume x in {Gik};
    then
A100: x = Gik by TARSKI:def 1;
A101: Gik in LSeg(go,m) by A48,RLTOPSP1:68;
    Gik in LSeg(pion1,1) by A41,A94,A99,TOPREAL1:21;
    hence thesis by A100,A101,XBOOLE_0:def 4;
  end;
  then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go }
  by A41,A44,A98;
  then
A102: go^'pion1 is unfolded by A94,TOPREAL8:34;
  len pion1 >= 2+0 by A86,FINSEQ_1:44;
  then
A103: len pion1-2 >= 0 by XREAL_1:19;
  len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
  then len (go^'pion1)-1 = len go + (len pion1-2)
    .= len go + (len pion1-'2) by A103,XREAL_0:def 2;
  then
A104: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A105: len pion1-1 >= 1 by A99,XREAL_1:19;
  then
A106: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A107: len pion1-'2+1 = len pion1-2+1 by A103,XREAL_0:def 2
    .= len pion1-'1 by A105,XREAL_0:def 2;
  len pion1-1+1 <= len pion1;
  then
A108: len pion1-'1 < len pion1 by A106,NAT_1:13;
  LSeg(pion1,len pion1-'1) c= L~<*Gik,Gij*> by A83,TOPREAL3:19;
  then LSeg(pion1,len pion1-'1) c= LSeg(Gik,Gij) by SPPOL_2:21;
  then
A109: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gij} by A58,XBOOLE_1:27;
  {Gij} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
  proof
    let x be object;
    assume x in {Gij};
    then
A110: x = Gij by TARSKI:def 1;
A111: Gij in LSeg(co,1) by A55,RLTOPSP1:68;
    pion1/.(len pion1-'1+1) = pion/.2 by A85,A106,FINSEQ_1:44
      .= Gij by FINSEQ_4:17;
    then Gij in LSeg(pion1,len pion1-'1) by A105,A106,TOPREAL1:21;
    hence thesis by A110,A111,XBOOLE_0:def 4;
  end;
  then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gij} by A109;
  then
A112: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) =
  {(go^'pion1)/.len (go^'pion1)} by A42,A94,A96,A107,A108,TOPREAL8:31;
A113: (go^'pion1) is non trivial by A89,NAT_D:60;
A114: rng pion1 c= L~pion1 by A99,SPPOL_2:18;
A115: {pion1/.1} c= L~go /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.1};
    then
A116: x = pion1/.1 by TARSKI:def 1;
    then
A117: x in rng go by A94,FINSEQ_6:168;
    x in rng pion1 by A116,FINSEQ_6:42;
    hence thesis by A61,A114,A117,XBOOLE_0:def 4;
  end;
  L~go /\ L~pion1 c= {pion1/.1}
  proof
    let x be object;
    assume
A118: x in L~go /\ L~pion1;
    then
A119: x in L~go by XBOOLE_0:def 4;
    x in L~pion1 by A118,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~US by A46,A119,XBOOLE_0:def 4;
    hence thesis by A6,A41,A83,A94,SPPOL_2:21;
  end;
  then
A120: L~go /\ L~pion1 = {pion1/.1} by A115;
  then
A121: (go^'pion1) is s.n.c. by A94,JORDAN1J:54;
  rng go /\ rng pion1 c= {pion1/.1} by A61,A114,A120,XBOOLE_1:27;
  then
A122: go^'pion1 is one-to-one by JORDAN1J:55;
A123: pion/.len pion = pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
A124: {pion1/.len pion1} c= L~co /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.len pion1};
    then
A125: x = pion1/.len pion1 by TARSKI:def 1;
    then
A126: x in rng co by A85,A123,FINSEQ_6:42;
    x in rng pion1 by A125,FINSEQ_6:168;
    hence thesis by A62,A114,A126,XBOOLE_0:def 4;
  end;
  L~co /\ L~pion1 c= {pion1/.len pion1}
  proof
    let x be object;
    assume
A127: x in L~co /\ L~pion1;
    then
A128: x in L~co by XBOOLE_0:def 4;
    x in L~pion1 by A127,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~LS by A53,A128,XBOOLE_0:def 4;
    hence thesis by A7,A42,A83,A85,A123,SPPOL_2:21;
  end;
  then
A129: L~co /\ L~pion1 = {pion1/.len pion1} by A124;
A130: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A94,TOPREAL8:35
    .= {go/.1} \/ {co/.1} by A73,A85,A123,A129,XBOOLE_1:23
    .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
    .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
  co/.len co = (go^'pion1)/.1 by A60,FINSEQ_6:155;
  then reconsider godo as non constant standard special_circular_sequence
  by A92,A96,A97,A102,A104,A112,A113,A121,A122,A130,JORDAN8:4,5,TOPREAL8:11,33
,34;
A131: LA is_an_arc_of E-max C,W-min C by JORDAN6:def 9;
  then
A132: LA is connected by JORDAN6:10;
A133: W-min C in LA by A131,TOPREAL1:1;
A134: E-max C in LA by A131,TOPREAL1:1;
  set ff = Rotate(Cage(C,n),Wmin);
  Wmin in rng Cage(C,n) by SPRECT_2:43;
  then
A135: ff/.1 = Wmin by FINSEQ_6:92;
A136: L~ff = L~Cage(C,n) by REVROT_1:33;
  then (W-max L~ff)..ff > 1 by A135,SPRECT_5:22;
  then (N-min L~ff)..ff > 1 by A135,A136,SPRECT_5:23,XXREAL_0:2;
  then (N-max L~ff)..ff > 1 by A135,A136,SPRECT_5:24,XXREAL_0:2;
  then
A137: Emax..ff > 1 by A135,A136,SPRECT_5:25,XXREAL_0:2;
A138: now
    assume
A139: Gik..US <= 1;
    Gik..US >= 1 by A34,FINSEQ_4:21;
    then Gik..US = 1 by A139,XXREAL_0:1;
    then Gik = US/.1 by A34,FINSEQ_5:38;
    hence contradiction by A18,A22,JORDAN1F:5;
  end;
A140: Cage(C,n) is_sequence_on Ga by JORDAN9:def 1;
  then
A141: ff is_sequence_on Ga by REVROT_1:34;
A142: right_cell(godo,1,Ga)\L~godo c= RightComp godo by A92,A97,JORDAN9:27;
A143: L~godo = L~(go^'pion1) \/ L~co by A96,TOPREAL8:35
    .= L~go \/ L~pion1 \/ L~co by A94,TOPREAL8:35;
A144: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
  then
A145: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A146: L~LS c= L~Cage(C,n) by A144,XBOOLE_1:7;
A147: L~go c= L~Cage(C,n) by A46,A145;
A148: L~co c= L~Cage(C,n) by A53,A146;
A149: W-min C in C by SPRECT_1:13;
A150: L~pion = LSeg(Gik,Gij) by SPPOL_2:21;
A151: now
    assume W-min C in L~godo;
    then
A152: W-min C in L~go \/ L~pion1 or W-min C in L~co by A143,XBOOLE_0:def 3;
    per cases by A152,XBOOLE_0:def 3;
    suppose W-min C in L~go;
      then C meets L~Cage(C,n) by A147,A149,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
    suppose W-min C in L~pion1;
      hence contradiction by A8,A83,A133,A150,XBOOLE_0:3;
    end;
    suppose W-min C in L~co;
      then C meets L~Cage(C,n) by A148,A149,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
  end;
  right_cell(Rotate(Cage(C,n),Wmin),1) =
  right_cell(ff,1,GoB ff) by A88,JORDAN1H:23
    .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
    .= right_cell(ff,1,Ga) by JORDAN1H:44
    .= right_cell(ff-:Emax,1,Ga) by A137,A141,JORDAN1J:53
    .= right_cell(US,1,Ga) by JORDAN1E:def 1
    .= right_cell(R_Cut(US,Gik),1,Ga) by A34,A93,A138,JORDAN1J:52
    .= right_cell(go^'pion1,1,Ga) by A39,A95,JORDAN1J:51
    .= right_cell(godo,1,Ga) by A90,A97,JORDAN1J:51;
  then W-min C in right_cell(godo,1,Ga) by JORDAN1I:6;
  then
A153: W-min C in right_cell(godo,1,Ga)\L~godo by A151,XBOOLE_0:def 5;
A154: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
    .= Wmin by A59,FINSEQ_6:155;
A155: len US >= 2 by A17,XXREAL_0:2;
A156: godo/.2 = (go^'pion1)/.2 by A89,FINSEQ_6:159
    .= US/.2 by A33,A76,FINSEQ_6:159
    .= (US^'LS)/.2 by A155,FINSEQ_6:159
    .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A157: L~go \/ L~co is compact by COMPTS_1:10;
  Wmin in L~go \/ L~co by A61,A77,XBOOLE_0:def 3;
  then
A158: W-min (L~go \/ L~co) = Wmin by A147,A148,A157,JORDAN1J:21,XBOOLE_1:8;
A160: Wmin`1 = Wbo;
  W-bound LSeg(Gik,Gij) = Gik`1 by A80,SPRECT_1:54;
  then
A161: W-bound L~pion1 = Gik`1 by A83,SPPOL_2:21;
  Gik`1 >= Wbo by A10,A145,PSCOMP_1:24;
  then Gik`1 > Wbo by A75,XXREAL_0:1;
  then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co)
  by A157,A158,A160,A161,JORDAN1J:33;
  then
A162: W-min L~godo = Wmin by A143,A158,XBOOLE_1:4;
A163: rng godo c= L~godo by A89,A91,SPPOL_2:18,XXREAL_0:2;
  2 in dom godo by A92,FINSEQ_3:25;
  then
A164: godo/.2 in rng godo by PARTFUN2:2;
  godo/.2 in W-most L~Cage(C,n) by A156,JORDAN1I:25;
  then (godo/.2)`1 = (W-min L~godo)`1 by A162,PSCOMP_1:31
    .= W-bound L~godo;
  then godo/.2 in W-most L~godo by A163,A164,SPRECT_2:12;
  then Rotate(godo,W-min L~godo)/.2 in W-most L~godo by A154,A162,FINSEQ_6:89;
  then reconsider godo as clockwise_oriented non constant standard
  special_circular_sequence by JORDAN1I:25;
  len US in dom US by FINSEQ_5:6;
  then
A165: US.len US = US/.len US by PARTFUN1:def 6
    .= Emax by JORDAN1F:7;
A166: east_halfline E-max C misses L~go
  proof
    assume east_halfline E-max C meets L~go;
    then consider p be object such that
A167: p in east_halfline E-max C and
A168: p in L~go by XBOOLE_0:3;
    reconsider p as Point of TOP-REAL 2 by A167;
    p in L~US by A46,A168;
    then p in east_halfline E-max C /\ L~Cage(C,n) by A145,A167,XBOOLE_0:def 4;
    then
 p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
    then
 p = Emax by A46,A168,JORDAN1J:46;
    then Emax = Gik by A10,A165,A168,JORDAN1J:43;
    then Gik`1 = Ga*(len Ga,k)`1 by A3,A13,A16,JORDAN1A:71;
    hence contradiction by A2,A15,A30,JORDAN1G:7;
  end;
  now
    assume east_halfline E-max C meets L~godo;
    then
A171: east_halfline E-max C meets (L~go \/ L~pion1) or
    east_halfline E-max C meets L~co by A143,XBOOLE_1:70;
    per cases by A171,XBOOLE_1:70;
    suppose east_halfline E-max C meets L~go;
      hence contradiction by A166;
    end;
    suppose east_halfline E-max C meets L~pion1;
      then consider p be object such that
A172: p in east_halfline E-max C and
A173: p in L~pion1 by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A172;
A174: p`1 = Gik`1 by A80,A83,A150,A173,GOBOARD7:5;
      i+1 <= len Ga by A2,NAT_1:13;
      then i+1-1 <= len Ga-1 by XREAL_1:9;
      then
A175: i <= len Ga-'1 by XREAL_0:def 2;
      len Ga-'1 <= len Ga by NAT_D:35;
      then p`1 <= Ga*(len Ga-'1,1)`1 by A1,A3,A13,A16,A20,A174,A175,JORDAN1A:18
;
      then p`1 <= E-bound C by A20,JORDAN8:12;
      then
A176: p`1 <= (E-max C)`1;
      p`1 >= (E-max C)`1 by A172,TOPREAL1:def 11;
      then
A177: p`1 = (E-max C)`1 by A176,XXREAL_0:1;
      p`2 = (E-max C)`2 by A172,TOPREAL1:def 11;
      then p = E-max C by A177,TOPREAL3:6;
      hence contradiction by A8,A83,A134,A150,A173,XBOOLE_0:3;
    end;
    suppose east_halfline E-max C meets L~co;
      then consider p be object such that
A178: p in east_halfline E-max C and
A179: p in L~co by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A178;
      p in L~LS by A53,A179;
      then p in east_halfline E-max C /\ L~Cage(C,n)
      by A146,A178,XBOOLE_0:def 4;
      then
A180: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A181: (E-max C)`2 = p`2 by A178,TOPREAL1:def 11;
      set RC = Rotate(Cage(C,n),Emax);
A182: E-max C in right_cell(RC,1) by JORDAN1I:7;
A183: 1+1 <= len LS by A23,XXREAL_0:2;
      LS = RC-:Wmin by JORDAN1G:18;
      then
A184: LSeg(LS,1) = LSeg(RC,1) by A183,SPPOL_2:9;
A185: L~RC = L~Cage(C,n) by REVROT_1:33;
A186: len RC = len Cage(C,n) by FINSEQ_6:179;
A187: GoB RC = GoB Cage(C,n) by REVROT_1:28
        .= Ga by JORDAN1H:44;
A188: Emax in rng Cage(C,n) by SPRECT_2:46;
A189: RC is_sequence_on Ga by A140,REVROT_1:34;
A190: RC/.1 = E-max L~RC by A185,A188,FINSEQ_6:92;
      consider ii,jj be Nat such that
A191: [ii,jj+1] in Indices Ga and
A192: [ii,jj] in Indices Ga and
A193: RC/.1 = Ga*(ii,jj+1) and
A194: RC/.(1+1) = Ga*(ii,jj) by A87,A185,A186,A188,A189,FINSEQ_6:92,JORDAN1I:23
;
      consider jj2 be Nat such that
A195: 1 <= jj2 and
A196: jj2 <= width Ga and
A197: Emax = Ga*(len Ga,jj2) by JORDAN1D:25;
A198: len Ga >= 4 by JORDAN8:10;
      then len Ga >= 1 by XXREAL_0:2;
      then [len Ga,jj2] in Indices Ga by A195,A196,MATRIX_0:30;
      then
A199: ii = len Ga by A185,A190,A191,A193,A197,GOBOARD1:5;
A200: 1 <= ii by A191,MATRIX_0:32;
A201: ii <= len Ga by A191,MATRIX_0:32;
A202: 1 <= jj+1 by A191,MATRIX_0:32;
A203: jj+1 <= width Ga by A191,MATRIX_0:32;
A204: 1 <= ii by A192,MATRIX_0:32;
A205: ii <= len Ga by A192,MATRIX_0:32;
A206: 1 <= jj by A192,MATRIX_0:32;
A207: jj <= width Ga by A192,MATRIX_0:32;
A208: ii+1 <> ii;
      jj+1+1 <> jj;
      then
A209: right_cell(RC,1) = cell(Ga,ii-'1,jj)
      by A87,A186,A187,A191,A192,A193,A194,A208,GOBOARD5:def 6;
A210: ii-'1+1 = ii by A200,XREAL_1:235;
      ii-1 >= 4-1 by A198,A199,XREAL_1:9;
      then
A211: ii-1 >= 1 by XXREAL_0:2;
      then
A212: 1 <= ii-'1 by XREAL_0:def 2;
A213: Ga*(ii-'1,jj)`2 <= p`2 by A181,A182,A201,A203,A206,A209,A210,A211,
JORDAN9:17;
A214: p`2 <= Ga*(ii-'1,jj+1)`2 by A181,A182,A201,A203,A206,A209,A210,A211,
JORDAN9:17;
A215: ii-'1 < len Ga by A201,A210,NAT_1:13;
      then
A216: Ga*(ii-'1,jj)`2 = Ga*(1,jj)`2 by A206,A207,A212,GOBOARD5:1
        .= Ga*(ii,jj)`2 by A204,A205,A206,A207,GOBOARD5:1;
A217: Ga*(ii-'1,jj+1)`2 = Ga*(1,jj+1)`2 by A202,A203,A212,A215,GOBOARD5:1
        .= Ga*(ii,jj+1)`2 by A200,A201,A202,A203,GOBOARD5:1;
A218: Ga*(len Ga,jj)`1 = Ebo by A16,A206,A207,JORDAN1A:71;
      Ebo = Ga*(len Ga,jj+1)`1 by A16,A202,A203,JORDAN1A:71;
      then p in LSeg(RC/.1,RC/.(1+1))
      by A180,A193,A194,A199,A213,A214,A216,A217,A218,GOBOARD7:7;
      then
A219: p in LSeg(LS,1) by A87,A184,A186,TOPREAL1:def 3;
A220: p in LSeg(co,Index(p,co)) by A179,JORDAN3:9;
A221: co = mid(LS,Gij..LS,len LS) by A37,JORDAN1J:37;
A222: 1<=Gij..LS by A37,FINSEQ_4:21;
A223: Gij..LS<=len LS by A37,FINSEQ_4:21;
      Gij..LS <> len LS by A29,A37,FINSEQ_4:19;
      then
A224: Gij..LS < len LS by A223,XXREAL_0:1;
A225: 1<=Index(p,co) by A179,JORDAN3:8;
A226: Index(p,co) < len co by A179,JORDAN3:8;
A227: Index(Gij,LS)+1 = Gij..LS by A32,A37,JORDAN1J:56;
      consider t be Nat such that
A228: t in dom LS and
A229: LS.t = Gij by A37,FINSEQ_2:10;
A230: 1 <= t by A228,FINSEQ_3:25;
A231: t <= len LS by A228,FINSEQ_3:25;
      1 < t by A32,A229,A230,XXREAL_0:1;
      then Index(Gij,LS)+1 = t by A229,A231,JORDAN3:12;
      then
A232: len L_Cut(LS,Gij) = len LS-Index(Gij,LS) by A9,A229,JORDAN3:26;
      set tt = Index(p,co)+(Gij..LS)-'1;
A233: 1<=Index(Gij,LS) by A9,JORDAN3:8;
      0+Index(Gij,LS) < len LS by A9,JORDAN3:8;
      then
A234: len LS-Index(Gij,LS) > 0 by XREAL_1:20;
      Index(p,co) < len LS-'Index(Gij,LS) by A226,A232,XREAL_0:def 2;
      then Index(p,co)+1 <= len LS-'Index(Gij,LS) by NAT_1:13;
      then Index(p,co) <= len LS-'Index(Gij,LS)-1 by XREAL_1:19;
      then Index(p,co) <= len LS-Index(Gij,LS)-1 by A234,XREAL_0:def 2;
      then Index(p,co) <= len LS-Gij..LS by A227;
      then Index(p,co) <= len LS-'Gij..LS by XREAL_0:def 2;
      then Index(p,co) < len LS-'(Gij..LS)+1 by NAT_1:13;
      then
A235: LSeg(mid(LS,Gij..LS,len LS),Index(p,co)) =
      LSeg(LS,Index(p,co)+(Gij..LS)-'1) by A222,A224,A225,JORDAN4:19;
A236: 1+1 <= Gij..LS by A227,A233,XREAL_1:7;
      then Index(p,co)+Gij..LS >= 1+1+1 by A225,XREAL_1:7;
      then Index(p,co)+Gij..LS-1 >= 1+1+1-1 by XREAL_1:9;
      then
A237: tt >= 1+1 by XREAL_0:def 2;
A238: 2 in dom LS by A183,FINSEQ_3:25;
      now per cases by A237,XXREAL_0:1;
        suppose tt > 1+1;
          then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
          hence contradiction by A219,A220,A221,A235,XBOOLE_0:3;
        end;
        suppose
A239:     tt = 1+1;
          then LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A23,TOPREAL1:def 6;
          then p in {LS/.2} by A219,A220,A221,A235,XBOOLE_0:def 4;
          then
A240:     p = LS/.2 by TARSKI:def 1;
          then
A241:     p..LS = 2 by A238,FINSEQ_5:41;
          1+1 = Index(p,co)+(Gij..LS)-1 by A239,XREAL_0:def 2;
          then 1+1+1 = Index(p,co)+(Gij..LS);
          then
A242:     Gij..LS = 2 by A225,A236,JORDAN1E:6;
          p in rng LS by A238,A240,PARTFUN2:2;
          then p = Gij by A37,A241,A242,FINSEQ_5:9;
          then Gij`1 = Ebo by A240,JORDAN1G:32;
          then Gij`1 = Ga*(len Ga,j)`1 by A5,A12,A16,JORDAN1A:71;
          hence contradiction by A2,A14,A67,JORDAN1G:7;
        end;
      end;
      hence contradiction;
    end;
  end;
  then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
  then consider W be Subset of TOP-REAL 2 such that
A243: W is_a_component_of (L~godo)` and
A244: east_halfline E-max C c= W by GOBOARD9:3;
  W is not bounded by A244,JORDAN2C:121,RLTOPSP1:42;
  then W is_outside_component_of L~godo by A243,JORDAN2C:def 3;
  then W c= UBD L~godo by JORDAN2C:23;
  then
A245: east_halfline E-max C c= UBD L~godo by A244;
  E-max C in east_halfline E-max C by TOPREAL1:38;
  then E-max C in UBD L~godo by A245;
  then E-max C in LeftComp godo by GOBRD14:36;
  then LA meets L~godo by A132,A133,A134,A142,A153,JORDAN1J:36;
  then
A246: LA meets (L~go \/ L~pion1) or LA meets L~co by A143,XBOOLE_1:70;
A247: LA c= C by JORDAN6:61;
  per cases by A246,XBOOLE_1:70;
  suppose LA meets L~go;
    then LA meets L~Cage(C,n) by A46,A145,XBOOLE_1:1,63;
    hence contradiction by A247,JORDAN10:5,XBOOLE_1:63;
  end;
  suppose LA meets L~pion1;
    hence contradiction by A8,A83,A150;
  end;
  suppose LA meets L~co;
    then LA meets L~Cage(C,n) by A53,A146,XBOOLE_1:1,63;
    hence contradiction by A247,JORDAN10:5,XBOOLE_1:63;
  end;
end;
