reserve i,j,k,n for Nat;

theorem Th13:
  for f being clockwise_oriented non constant standard
special_circular_sequence for G being Go-board st f is_sequence_on G for i,j,k
being Nat st 1 <= k & k+1 <= len f & [i,j] in Indices G & [i+1,j] in
  Indices G & f/.k = G*(i+1,j) & f/.(k+1) = G*(i,j) holds j < width G
proof
  let f be clockwise_oriented non constant standard special_circular_sequence;
  let G be Go-board;
  assume
A1: f is_sequence_on G;
  let i,j,k be Nat;
  assume that
A2: 1 <= k & k+1 <= len f and
A3: [i,j] in Indices G and
A4: [i+1,j] in Indices G & f/.k = G*(i+1,j) & f/.(k+1) = G*(i,j);
  assume
A5: j >= width G;
  j <= width G by A3,MATRIX_0:32;
  then
A6: j = width G by A5,XXREAL_0:1;
A7: i <= len G by A3,MATRIX_0:32;
  right_cell(f,k,G) = cell(G,i,j) by A1,A2,A3,A4,GOBRD13:26;
  then right_cell(f,k,G)\L~f is not bounded by A7,A6,JORDAN1A:27,TOPREAL6:90;
  then RightComp f is not bounded by A1,A2,JORDAN9:27,RLTOPSP1:42;
  then BDD L~f is not bounded by GOBRD14:37;
  hence contradiction by JORDAN2C:106;
end;
