reserve j for Nat;

theorem Th13:
  for P being non empty Subset of TOP-REAL 2, P1 being Subset of (
TOP-REAL 2)|P,Q being Subset of I[01], f being Function of I[01],(TOP-REAL 2)|P
  ,s being Real st s<=1 & P1= {q0 where q0 is Point of TOP-REAL 2:
 ex ss being
  Real st 0<=ss & ss<s & q0=f.ss} & Q=[.0,s.[ holds f.:Q=P1
proof
  let P be non empty Subset of TOP-REAL 2, P1 be Subset of (TOP-REAL 2)|P, Q
  be Subset of I[01], f be Function of I[01],(TOP-REAL 2)|P,
   s be Real;
  assume that
A1: s<=1 and
A2: P1= {q0 where q0 is Point of TOP-REAL 2:
  ex ss being Real st 0<=ss &
  ss<s & q0=f.ss} and
A3: Q=[.0,s.[;
A4: the carrier of (TOP-REAL 2)|P=P by PRE_TOPC:8;
A5: f.:Q c= P1
  proof
    let y be object;
    assume y in f.:Q;
    then consider z being object such that
A6: z in dom f and
A7: z in Q and
A8: f.z=y by FUNCT_1:def 6;
    reconsider ss=z as Real by A6;
    y in rng f by A6,A8,FUNCT_1:def 3;
    then y in P by A4;
    then reconsider q=y as Point of TOP-REAL 2;
    0<=ss & ss<s by A3,A7,XXREAL_1:3;
    then ex ss being Real st 0<=ss & ss<s & q=f.ss by A8;
    hence thesis by A2;
  end;
  P1 c= f.:Q
  proof
    let x be object;
A9: dom f= [.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
    assume x in P1;
    then consider q0 being Point of TOP-REAL 2 such that
A10: q0=x and
A11: ex ss being Real st 0<=ss & ss<s & q0=f.ss by A2;
    consider ss being Real such that
A12: 0<=ss and
A13: ss<s and
A14: q0=f.ss by A11;
    ss<1 by A1,A13,XXREAL_0:2;
    then
A15: ss in dom f by A12,A9,XXREAL_1:1;
    ss in Q by A3,A12,A13,XXREAL_1:3;
    hence thesis by A10,A14,A15,FUNCT_1:def 6;
  end;
  hence thesis by A5,XBOOLE_0:def 10;
end;
