reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th13:
  0 < n implies upper_bound (proj2.:(L~Cage(C,n) /\ LSeg(Gauge(C,n)*(
Center Gauge(C,n),1), Gauge(C,n)*(Center Gauge(C,n),len Gauge(C,n)))))
 = upper_bound (
proj2.:(L~Cage(C,n) /\ Vertical_Line ((E-bound L~Cage(C,n) + W-bound L~Cage(C,n
  )) / 2)))
proof
  set f = Cage(C,n), G = Gauge(C,n), c = Center G;
  set Y = proj2.:(L~f /\ Vertical_Line ((E-bound L~f + W-bound L~f) / 2));
  set X = proj2.:(L~f /\ LSeg(G*(c,1),G*(c,len G)));
A1: len G = width G by JORDAN8:def 1;
A2: 1 <= len G by Lm3;
  assume 0 < n;
  then
A3: G*(c,1)`1 = (W-bound C + E-bound C) / 2 by A1,A2,JORDAN1G:35
    .= (W-bound L~f + E-bound L~f) / 2 by JORDAN1G:33;
  then
A4: G*(c,1) in Vertical_Line ((E-bound L~f + W-bound L~f) / 2);
A5: Y is bounded_above by JORDAN21:13;
  LSeg(G*(c,1),G*(c,len G)) meets Upper_Arc L~f by JORDAN1B:31;
  then LSeg(G*(c,1),G*(c,len G)) meets L~f by JORDAN6:61,XBOOLE_1:63;
  then
A6: L~f /\ LSeg(G*(c,1),G*(c,len G)) is non empty by XBOOLE_0:def 7;
  then
A7: X is non empty by Lm2,RELAT_1:119;
A8: c <= len G by JORDAN1B:13;
  1 <= c by JORDAN1B:11;
  then
A9: G*(c,1)`1 = G*(c,len G)`1 by A1,A2,A8,GOBOARD5:2;
  then G*(c,len G) in Vertical_Line ((E-bound L~f + W-bound L~f) / 2) by A3;
  then
A10: L~f /\ L~f /\ LSeg(G*(c,1),G*(c,len G)) c= L~f /\ Vertical_Line ((
  E-bound L~f + W-bound L~f) / 2) by A4,JORDAN1A:13,XBOOLE_1:26;
  then
A11: X c= Y by RELAT_1:123;
  then
A12: for r being Real st r in X holds r<=upper_bound Y
by A5,SEQ_4:def 1;
A13: Y is non empty by A11,A6,Lm2,RELAT_1:119,XBOOLE_1:3;
A14: for s being Real st 0<s ex r being Real st r in X &
  upper_bound Y-s < r
  proof
    let s be Real;
    assume 0<s;
    then consider r being Real such that
A15: r in Y and
A16: upper_bound Y-s<r by A5,A13,SEQ_4:def 1;
    take r;
    consider x being Point of TOP-REAL 2 such that
A17: x in L~f /\ Vertical_Line ((E-bound L~f + W-bound L~f) / 2) and
A18: proj2.x = r by A15,Lm1;
A19: x in L~f by A17,XBOOLE_0:def 4;
    x in Vertical_Line ((E-bound L~f + W-bound L~f)/2) by A17,XBOOLE_0:def 4;
    then
A20: G*(c,1)`1 = x`1 by A3,JORDAN6:31;
A21: GoB f = G by JORDAN1H:44;
    then
A22: G*(c,1)`2 <= x`2 by A8,A19,JORDAN1B:11,JORDAN5D:33;
    x`2 <= G*(c,len G)`2 by A1,A8,A19,A21,JORDAN1B:11,JORDAN5D:34;
    then x in LSeg(G*(c,1),G*(c,len G)) by A9,A20,A22,GOBOARD7:7;
    then x in L~f /\ LSeg(G*(c,1),G*(c,len G)) by A19,XBOOLE_0:def 4;
    hence r in X by A18,FUNCT_2:35;
    thus thesis by A16;
  end;
  X is bounded_above by A10,A5,RELAT_1:123,XXREAL_2:43;
  hence thesis by A7,A12,A14,SEQ_4:def 1;
end;
