reserve p,p1,p2,p3,q for Point of TOP-REAL 2;

theorem Th13:
  for P being compact non empty Subset of TOP-REAL 2, q1,q2,q3,q4
  being Point of TOP-REAL 2 st P is being_simple_closed_curve & LE q1,q2,P & LE
q2,q3,P & LE q3,q4,P & q1<>q2 & q2<>q3 holds Segment(q1,q2,P) misses Segment(q3
  ,q4,P)
proof
  let P be compact non empty Subset of TOP-REAL 2, q1,q2,q3,q4 be Point of
  TOP-REAL 2;
  assume that
A1: P is being_simple_closed_curve and
A2: LE q1,q2,P and
A3: LE q2,q3,P and
A4: LE q3,q4,P and
A5: q1<>q2 and
A6: q2<>q3;
  set x = the Element of Segment(q1,q2,P)/\ Segment(q3,q4,P);
  assume
A7: Segment(q1,q2,P)/\ Segment(q3,q4,P)<>{};
  then
A8: x in Segment(q1,q2,P) by XBOOLE_0:def 4;
A9: x in Segment(q3,q4,P) by A7,XBOOLE_0:def 4;
  per cases;
  suppose
    q4=W-min(P);
    then q3=W-min(P) by A1,A4,Th2;
    hence contradiction by A1,A3,A6,Th2;
  end;
  suppose
A10: q4<>W-min(P);
    q2<>W-min(P) by A1,A2,A5,Th2;
    then x in {p2: LE q1,p2,P & LE p2,q2,P} by A8,Def1;
    then
A11: ex p2 st p2=x & LE q1,p2,P & LE p2,q2,P;
    x in {p1: LE q3,p1,P & LE p1,q4,P} by A9,A10,Def1;
    then ex p1 st p1=x & LE q3,p1,P & LE p1,q4,P;
    then LE q3,q2,P by A1,A11,JORDAN6:58;
    hence contradiction by A1,A3,A6,JORDAN6:57;
  end;
end;
