reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem Th13:
  f is_sequence_on G & LSeg(f,k) is vertical implies ex i st 1 <=
  i & i <= len G & for p st p in LSeg(f,k) holds p`1 = G*(i,1)`1
proof
  assume that
A1: f is_sequence_on G and
A2: LSeg(f,k) is vertical;
  per cases;
  suppose
A3: 1 <= k & k+1 <= len f;
    k <= k+1 by NAT_1:11;
    then k <= len f by A3,XXREAL_0:2;
    then consider i,j being Nat such that
A4: [i,j] in Indices G and
A5: f/.k = G*(i,j) by A1,A3,Lm2;
     reconsider i as Nat;
    take i;
    thus
A6: 1 <= i & i <= len G by A4,MATRIX_0:32;
A7: f/.k in LSeg(f,k) by A3,TOPREAL1:21;
    let p;
A8: 1 <= j & j <= width G by A4,MATRIX_0:32;
    assume p in LSeg(f,k);
    hence p`1 = (f/.k)`1 by A2,A7,SPPOL_1:def 3
      .= G*(i,1)`1 by A5,A6,A8,GOBOARD5:2;
  end;
  suppose
A9: not(1 <= k & k+1 <= len f);
    take 1;
    0 <> len G by MATRIX_0:def 10;
    hence 1 <= 1 & 1 <= len G by NAT_1:14;
    thus thesis by A9,TOPREAL1:def 3;
  end;
end;
