reserve Omega, I for non empty set;
reserve Sigma for SigmaField of Omega;
reserve P for Probability of Sigma;
reserve D, E, F for Subset-Family of Omega;
reserve  B, sB for non empty Subset of Sigma;
reserve b for Element of B;
reserve a for Element of Sigma;
reserve p, q, u, v for Event of Sigma;
reserve n, m for Element of NAT;
reserve S, S9, X, x, y, z, i, j for set;

theorem Th13:
  for F being ManySortedSigmaField of I,Sigma, J being non empty
  Subset of I holds MeetSections(J,F) is non empty Subset of Sigma
proof
  let F be ManySortedSigmaField of I,Sigma, J be non empty Subset of I;
A1: MeetSections(J,F) c= Sigma
  proof
    let X be object;
    assume X in MeetSections(J,F);
    then consider
    E being non empty finite Subset of I, f being SigmaSection of E,F
    such that
    E c= J and
A2: X = meet rng f by Def9;
    reconsider Ee=E as Element of Fin E by FINSUB_1:def 5;
    for B being Element of Fin E holds meet rng (f|B) in Sigma
    proof
      defpred P[set] means meet rng (f|$1) in Sigma;
      let B be Element of Fin E;
A3:   for B9 being (Element of Fin E), b being Element of E holds P[B9] &
      not b in B9 implies P[B9 \/ {b}]
      proof
        let B9 be (Element of Fin E), b be Element of E;
        assume that
A4:     meet rng (f|B9) in Sigma and
        not b in B9;
A5:     rng (f|(B9 \/ {b})) = rng ((f|B9) \/ f|{b}) by RELAT_1:78
          .= (rng (f|B9)) \/ rng (f|{b}) by RELAT_1:12;
        dom f = E & b in {b} by FUNCT_2:def 1,TARSKI:def 1;
        then
A6:     f.b in rng(f|{b}) by FUNCT_1:50;
A7:     b is Element of dom f by FUNCT_2:def 1;
        then dom f /\ {b} = {b} by ZFMISC_1:46;
        then dom (f|{b}) = {b} by RELAT_1:61;
        then
A8:     rng (f|{b}) = {(f|{b}).b} by FUNCT_1:4;
        b in {b} by TARSKI:def 1;
        then b in dom (f|{b}) by A7,RELAT_1:57;
        then rng (f|{b}) = {f.b} by A8,FUNCT_1:47;
        then
A9:     meet rng (f|{b}) is Event of Sigma by SETFAM_1:10;
        per cases;
        suppose
          rng (f|B9) = {};
          hence thesis by A9,A5;
        end;
        suppose
          not rng (f|B9) = {};
          then meet rng (f|(B9 \/ {b}))= meet rng (f|B9) /\ meet rng (f|{b})
          by A5,A6,SETFAM_1:9;
          then meet rng (f|(B9 \/ {b})) is Event of Sigma by A4,A9,PROB_1:19;
          hence thesis;
        end;
      end;
      meet rng (f|{}) = {} by SETFAM_1:def 1;
      then
A10:  P[{}.E] by PROB_1:4;
      for B1 being Element of Fin E holds P[B1] from SETWISEO:sch 2 ( A10
      ,A3);
      hence thesis;
    end;
    then meet rng (f|Ee) in Sigma;
    hence thesis by A2;
  end;
  MeetSections(J,F) is non empty set
  proof
    set E = the non empty finite Subset of J;
    consider f being Function such that
A11: dom f = E and
A12: rng f = {{}} by FUNCT_1:5;
    reconsider E as non empty finite Subset of I by XBOOLE_1:1;
A13: meet rng f = {} by A12,SETFAM_1:10;
    rng f c= Sigma
    proof
      let y be object;
      assume y in rng f;
      then y={} by A12,TARSKI:def 1;
      hence thesis by PROB_1:4;
    end;
    then reconsider f as Function of E, Sigma by A11,FUNCT_2:2;
    for i st i in E holds f.i in F.i
    proof
      let i;
      assume
A14:  i in E;
      then reconsider Fi=F.i as SigmaField of Omega by Def2;
      f.i in rng f by A11,A14,FUNCT_1:def 3;
      then f.i = {} by A12,TARSKI:def 1;
      then f.i in Fi by PROB_1:4;
      hence thesis;
    end;
    then reconsider f as SigmaSection of E,F by Def4;
    reconsider mrf=meet rng f as Subset of Omega by A13,XBOOLE_1:2;
    mrf in MeetSections(J,F) by Def9;
    hence thesis;
  end;
  hence thesis by A1;
end;
