reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;

theorem Th13:
  Y+y c= X+x iff Y+(y-x) c= X
proof
  thus Y+y c= X+x implies Y+(y-x) c= X
  proof
    assume
A1: Y+y c= X+x;
    let p be object;
    assume p in Y+(y-x);
    then consider q1 being Point of T such that
A2: p = q1 + (y-x) and
A3: q1 in Y;
    reconsider p as Point of T by A2;
    p = q1 + y - x by A2,RLVECT_1:28; then
A4: p + x = q1 + y by Lm2;
    q1 + y in {q+y where q is Point of T:q in Y} by A3;
    then p + x in X + x by A1,A4;
    then consider p1 being Point of T such that
A5: p+x =p1+x and
A6: p1 in X;
    p +x-x= p1 by A5,Lm2;
    hence thesis by A6,Lm2;
  end;
  assume
A7: Y+(y-x) c= X;
  let p be object;
  assume p in Y+y;
  then consider q1 being Point of T such that
A8: p = q1 + y and
A9: q1 in Y;
  reconsider p as Point of T by A8;
  p-x = q1 + (y -x) & q1+(y-x) in {q+(y-x) where q is Point of T
  :q in Y} by A8,A9,RLVECT_1:28;
  then (p-x)+x in {q+x where q is Point of T:q in X}by A7;
  hence thesis by Lm2;
end;
