reserve x,y for set,
  i,j,k,l,m,n for Nat,
  K for Field,
  N for without_zero finite Subset of NAT,
  a,b for Element of K,
  A,B,B1,B2,X,X1,X2 for (Matrix of K),
  A9 for (Matrix of m,n,K),
  B9 for (Matrix of m,k,K);

theorem Th13:
  for V be VectSp of K for U be finite Subset of V for u, v be
Vector of V,a st u in U & v in U holds Lin (U \ {u} \/ {u+a*v}) is Subspace of
  Lin U
proof
  let V be VectSp of K;
  let U be finite Subset of V;
  let u, v be Vector of V,a such that
A1: u in U & v in U;
  set ua=u+a*v;
  set UU=U\{u};
  UU \/ {ua} c= the carrier of Lin U
  proof
    let x be object such that
A2: x in UU \/ {ua};
    per cases by A2,XBOOLE_0:def 3;
    suppose
      x in UU;
      then x in U by XBOOLE_0:def 5;
      then x in Lin U by VECTSP_7:8;
      hence thesis by STRUCT_0:def 5;
    end;
    suppose
A3:   x in {ua};
A4:   u in Lin U & a*v in Lin U by A1,VECTSP_4:21,VECTSP_7:8;
      x=ua by A3,TARSKI:def 1;
      then x in Lin U by A4,VECTSP_4:20;
      hence thesis by STRUCT_0:def 5;
    end;
  end;
  hence thesis by VECTSP_9:16;
end;
