
theorem Th13:
for n be non zero Nat, X be non-empty (n+1)-element FinSequence,
 x,y be object st x in CarProduct SubFin(X,n) & y in ElmFin(X,n+1)
  ex s,t be FinSequence st
   (CarProd SubFin(X,n)).x = s & <*y*> = t & (CarProd X).(x,y) = s^t
proof
    let n be non zero Nat, X be non-empty (n+1)-element FinSequence,
    x,y be object;
    assume
A1: x in CarProduct SubFin(X,n) & y in ElmFin(X,n+1);

A2: n < n+1 by NAT_1:13; then
    consider F be Function of CarProduct SubFin(X,n),product SubFin(X,n),
     G be Function of [: CarProduct SubFin(X,n),ElmFin(X,n+1):],
        product SubFin(X,n+1) such that
A3: F = (Pt2FinSeq X).n & G = (Pt2FinSeq X).(n+1) & F is bijective
  & G is bijective
  & for x,y be object st x in CarProduct SubFin(X,n) & y in ElmFin(X,n+1)
      ex s be FinSequence st F.x = s & G.(x,y) = s^<*y*> by Def5;

    consider s be FinSequence such that
A4: F.x = s & G.(x,y) = s^<*y*> by A1,A3;
    set t = <*y*>;
    take s,t;
    thus (CarProd SubFin(X,n)).x = s & <*y*> = t & (CarProd X).(x,y) = s^t
      by A3,A4,A2,Th10;
end;
