reserve X for non empty set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  E for Element of S,
  F,G for Functional_Sequence of X,ExtREAL,
  I for ExtREAL_sequence,
  f,g for PartFunc of X,ExtREAL,
  seq, seq1, seq2 for ExtREAL_sequence,
  p for ExtReal,
  n,m for Nat,
  x for Element of X,
  z,D for set;

theorem Th13:
  E = dom f & f is E-measurable & f is nonnegative & M.(E /\
  eq_dom(f,+infty)) <> 0 implies Integral(M,f) = +infty
proof
  assume that
A1: E = dom f and
A2: f is E-measurable and
A3: f is nonnegative and
A4: M.(E /\ eq_dom(f,+infty)) <> 0;
  reconsider EE = E /\ eq_dom(f,+infty) as Element of S by A1,A2,MESFUNC1:33;
A5: dom(f|E) = E by A1;
  E = dom f /\ E by A1;
  then
A6: f|E is E-measurable by A2,MESFUNC5:42;
  integral+(M,f|EE) <= integral+(M,f|E) by A1,A2,A3,MESFUNC5:83,XBOOLE_1:17;
  then
A7: integral+(M,f|EE) <= Integral(M,f|E) by A3,A6,A5,MESFUNC5:15,88;
A8: EE = dom f /\ EE by A1,XBOOLE_1:17,28;
  f is EE-measurable by A2,MESFUNC1:30,XBOOLE_1:17;
  then
A9: f|EE is EE-measurable by A8,MESFUNC5:42;
A10: f|EE is nonnegative by A3,MESFUNC5:15;
  reconsider ES = {} as Element of S by PROB_1:4;
  deffunc G(Element of NAT) = $1(#)((chi(EE,X))|EE);
  consider G be Function such that
A11: dom G = NAT & for n be Element of NAT holds G.n = G(n) from FUNCT_1
  :sch 4;
  now
    let g be object;
    assume g in rng G;
    then consider m be object such that
A12: m in dom G and
A13: g = G.m by FUNCT_1:def 3;
    reconsider m as Element of NAT by A11,A12;
    g = m(#)((chi(EE,X))|EE) by A11,A13;
    hence g in PFuncs(X,ExtREAL) by PARTFUN1:45;
  end;
  then rng G c= PFuncs(X,ExtREAL);
  then reconsider G as Functional_Sequence of X,ExtREAL by A11,FUNCT_2:def 1
,RELSET_1:4;
A14: for n be Nat holds dom(G.n) = EE & for x be set st x in dom(G.n) holds (
  G.n).x = n
  proof
    let n be Nat;
    reconsider n1 = n as Element of NAT by ORDINAL1:def 12;
    EE c= X;
    then EE c= dom(chi(EE,X)) by FUNCT_3:def 3;
    then
A15: dom((chi(EE,X))|EE) = EE by RELAT_1:62;
A16: G.n = n1(#)((chi(EE,X))|EE) by A11;
    hence
A17: dom(G.n) = EE by A15,MESFUNC1:def 6;
    let x be set;
    assume
A18: x in dom(G.n);
    then reconsider x1=x as Element of X;
    chi(EE,X).x1 = 1. by A17,A18,FUNCT_3:def 3;
    then ((chi(EE,X))|EE).x1 = 1. by A15,A17,A18,FUNCT_1:47;
    then (G.n).x = ( n1) * 1. by A16,A18,MESFUNC1:def 6;
    hence thesis by XXREAL_3:81;
  end;
A19: for n be Nat holds G.n is nonnegative
  proof
    let n be Nat;
    for x be object st x in dom(G.n) holds 0 <= (G.n).x by A14;
    hence thesis by SUPINF_2:52;
  end;
  deffunc K(Element of NAT) = integral'(M,G.$1);
  consider K be sequence of ExtREAL such that
A20: for n be Element of NAT holds K.n = K(n) from FUNCT_2:sch 4;
  reconsider K as ExtREAL_sequence;
A21: for n be Nat holds K.n=integral'(M,G.n)
  proof
    let n be Nat;
    reconsider n1=n as Element of NAT by ORDINAL1:def 12;
    K.n = integral'(M,G.n1) by A20;
    hence thesis;
  end;
A22: dom(f|EE) = EE by A1,RELAT_1:62,XBOOLE_1:17;
A23: for n,m be Nat st n <=m holds for x be Element of X st x in dom(f|EE)
  holds (G.n).x <= (G.m).x
  proof
    let n,m be Nat such that
A24: n <= m;
    let x be Element of X;
    assume
A25: x in dom(f|EE);
    then x in dom(G.n) by A22,A14;
    then
A26: (G.n).x = n by A14;
    x in dom(G.m) by A22,A14,A25;
    hence thesis by A14,A24,A26;
  end;
A27: for n be Nat holds dom(G.n) = dom(f|EE) & G.n is_simple_func_in S
  proof
    let n be Nat;
    reconsider n1 = n as Element of NAT by ORDINAL1:def 12;
    thus
A28: dom(G.n) = dom(f|EE) by A22,A14;
    for x be object st x in dom(G.n) holds (G.n).x = n1 by A14;
    hence thesis by A22,A28,MESFUNC6:2;
  end;
A29: for i be Element of NAT holds K.i = ( i)*(M.(dom(G.i)))
  proof
    let i be Element of NAT;
     reconsider ii=i as R_eal by XXREAL_0:def 1;
    for x be object st x in dom(G.i) holds (G.ii).x =  ii by A14;
    then integral'(M,G.i) = (ii)*(M.(dom(G.ii)))
            by A27,MESFUNC5:71;
    hence thesis by A21;
  end;
  M.ES <= M.EE by MEASURE1:31,XBOOLE_1:2;
  then
A30: In(0,REAL) < M.EE by A4,VALUED_0:def 19;
A31: not rng K is bounded_above
  proof
    assume rng K is bounded_above;
    then consider UB be Real such that
A32: UB is UpperBound of rng K by XXREAL_2:def 10;
    reconsider r = UB as Real;
    per cases by A30,XXREAL_0:10;
    suppose
A33:  M.EE = +infty;
      K.1 = ( 1) * (M.(dom(G.1))) by A29;
      then K.1 = ( 1) * (M.EE) by A14;
      then
A34:  K.1 = +infty by A33,XXREAL_3:def 5;
      dom K = NAT by FUNCT_2:def 1;
      then K.1 in rng K by FUNCT_1:3;
      then K.1 <= UB by A32,XXREAL_2:def 1;
      hence contradiction by A34,XXREAL_0:4;
    end;
    suppose
      M.EE in REAL;
      then reconsider ee = M.EE as Real;
      consider n be Nat such that
A35:  r/ee < n by SEQ_4:3;
A36:   n in NAT by ORDINAL1:def 12;
      K.n = ( n) * (M.(dom(G.n))) by A29,A36;
      then K.n = ( n) * (M.EE) by A14;
      then
A37:  K.n = n * ee by EXTREAL1:1;
      (r/ee) * ee < n * ee by A30,A35,XREAL_1:68;
      then r / (ee/ee) < K.n by A37,XCMPLX_1:82;
      then
A38:  r < K.n by A4,XCMPLX_1:51;
      dom K = NAT by FUNCT_2:def 1;
      then K.n in rng K by FUNCT_1:3,A36;
      then K.n <= r by A32,XXREAL_2:def 1;
      hence contradiction by A38;
    end;
  end;
  for n,m be Nat st m <= n holds K.m <= K.n
  proof
    let n,m be Nat;
A39: n in NAT by ORDINAL1:def 12;
A40: m in NAT by ORDINAL1:def 12;
    dom(G.m) = EE by A14;
    then
A41: K.m = ( m)*M.EE by A29,A40;
    dom(G.n) = EE by A14;
    then
A42: K.n = ( n)*M.EE by A29,A39;
    assume m <= n;
    hence thesis by A30,A41,A42,XXREAL_3:71;
  end;
  then
A43: K is non-decreasing by RINFSUP2:7;
  then
A44: lim K = sup K by RINFSUP2:37;
A45: for x be Element of X st x in dom(f|EE) holds G#x is convergent & lim(G#
  x) = (f|EE).x
  proof
    let x be Element of X;
    assume
A46: x in dom(f|EE);
    then
A47: x in EE by A1,RELAT_1:62,XBOOLE_1:17;
    then x in eq_dom(f,+infty) by XBOOLE_0:def 4;
    then f.x = +infty by MESFUNC1:def 15;
    then
A48: (f|EE).x = +infty by A47,FUNCT_1:49;
A49: rng(G#x) is not bounded_above
    proof
      assume rng(G#x) is bounded_above;
      then consider UB be Real such that
A50:  UB is UpperBound of rng(G#x) by XXREAL_2:def 10;
      reconsider r = UB as Real;
      consider n be Nat such that
A51:  r < n by SEQ_4:3;
      x in dom(G.n) by A14,A47;
      then (G.n).x = n by A14;
      then
A52:  UB < (G#x).n by A51,MESFUNC5:def 13;
A53:   n in NAT by ORDINAL1:def 12;
      dom(G#x) = NAT by FUNCT_2:def 1;
      then (G#x).n in rng(G#x) by FUNCT_1:3,A53;
      hence contradiction by A52,A50,XXREAL_2:def 1;
    end;
    for n,m be Nat st m<=n holds (G#x).m <= (G#x).n
    proof
      let n,m be Nat;
      dom(G.n) = EE by A14;
      then
A54:  (G.n).x = n by A22,A14,A46;
      dom(G.m) = EE by A14;
      then (G.m).x = m by A22,A14,A46;
      then
A55:  (G#x).m = m by MESFUNC5:def 13;
      assume m <= n;
      hence thesis by A54,A55,MESFUNC5:def 13;
    end;
    then
A56: G#x is non-decreasing by RINFSUP2:7;
    sup rng(G#x) is UpperBound of rng(G#x) by XXREAL_2:def 3;
    then sup(G#x) = +infty by A49,XXREAL_2:53;
    hence thesis by A56,A48,RINFSUP2:37;
  end;
  sup rng K is UpperBound of rng K by XXREAL_2:def 3;
  then
A57: sup K = +infty by A31,XXREAL_2:53;
  K is convergent by A43,RINFSUP2:37;
  then integral+(M,f|EE) = +infty by A10,A22,A9,A27,A19,A23,A45,A21,A44,A57,
MESFUNC5:def 15;
  then Integral(M,f|E) = +infty by A7,XXREAL_0:4;
  hence thesis by A1;
end;
