reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th13:
  for T st for F st F is open & F is Cover of T ex G st G c= F & G
  is Cover of T & card G c= C holds for A st A is closed & A is discrete holds
  card A c= C
proof
  let T;
  assume
A1: for F st F is open & F is Cover of T ex G st G c=F & G is Cover of T
  & card G c=C;
  set TOP=the topology of T;
  let A such that
A2: A is closed and
A3: A is discrete;
  A` in TOP by A2,PRE_TOPC:def 2;
  then
A4: {A`}c=TOP by ZFMISC_1:31;
  defpred Q[object,object] means ex D1 being set st D1 = $1 & {$2}=D1/\A;
  defpred P[object,object] means ex D2 being set st D2 = $2 & A/\D2={$1};
A5: for x be object st x in A ex y be object st y in TOP & P[x,y]
  proof
    let x be object;
    assume x in A;
    then consider G be Subset of T such that
A6: G is open & A/\G={x} by A3,TEX_2:26;
    take G;
    thus thesis by A6;
  end;
  consider p be Function of A,TOP such that
A7: for x be object st x in A holds P[x,p.x] from FUNCT_2:sch 1(A5);
  reconsider RNG=rng p,AA={A`} as open Subset-Family of T by A4,TOPS_2:11
,XBOOLE_1:1;
  reconsider RngA=RNG\/AA as open Subset-Family of T by TOPS_2:13;
  [#]T c=union RngA
  proof
    let x be object;
    assume
A8: x in [#]T;
    per cases;
    suppose
A9:   x in A;
      dom p=A by FUNCT_2:def 1;
      then p.x in rng p by A9,FUNCT_1:def 3;
      then
A10:  p.x in RngA by XBOOLE_0:def 3;
      P[x,p.x] by A7,A9;
      then x in {x} & A/\(p.x)={x} by TARSKI:def 1;
      then x in p.x by XBOOLE_0:def 4;
      hence thesis by A10,TARSKI:def 4;
    end;
    suppose
A11:  not x in A;
      A` in AA by TARSKI:def 1;
      then
A12:  A` in RngA by XBOOLE_0:def 3;
      x in A` by A8,A11,XBOOLE_0:def 5;
      hence thesis by A12,TARSKI:def 4;
    end;
  end;
  then RngA is Cover of T by SETFAM_1:def 11;
  then consider G be Subset-Family of T such that
A13: G c=RngA and
A14: G is Cover of T and
A15: card G c=C by A1;
A16: for x be object st x in G\AA ex y be object st y in A & Q[x,y]
  proof
    let x be object;
    assume x in G\AA;
    then x in G & not x in AA by XBOOLE_0:def 5;
    then x in RNG by A13,XBOOLE_0:def 3;
    then consider y be object such that
A17: y in dom p & p.y=x by FUNCT_1:def 3;
   take y;
    P[y,p.y] by A7,A17;
   hence thesis by A17;
  end;
  consider q be Function of G\AA,A such that
A18: for x be object st x in G\AA holds Q[x,q.x] from FUNCT_2:sch 1(A16);
  per cases;
  suppose
    A is empty;
    hence thesis;
  end;
  suppose
    A is non empty;
    then
A19: dom q=G\AA by FUNCT_2:def 1;
    A c=rng q
    proof
      let x be object such that
A20:  x in A;
      T is non empty by A20;
      then consider U be Subset of T such that
A21:  x in U and
A22:  U in G by A14,A20,PCOMPS_1:3;
      not x in A` by A20,XBOOLE_0:def 5;
      then not U in AA by A21,TARSKI:def 1;
      then
A23:    U in G\AA by A22,XBOOLE_0:def 5;
      then Q[U,q.U] by A18;
      then
A24:  q.U in rng q & {q.U}=U/\A by A19,FUNCT_1:def 3,A23;
      x in A/\U by A20,A21,XBOOLE_0:def 4;
      hence thesis by A24,TARSKI:def 1;
    end;
    then
A25: card A c=card(G\AA) by A19,CARD_1:12;
    card(G\AA)c=card G by CARD_1:11,XBOOLE_1:36;
    then card A c=card G by A25;
    hence card A c=C by A15;
  end;
end;
