reserve k,n,m for Nat,
  a,x,X,Y for set,
  D,D1,D2,S for non empty set,
  p,q for FinSequence of NAT;
reserve F,F1,G,G1,H,H1,H2 for LTL-formula;
reserve sq,sq9 for FinSequence;

theorem Th13:
  H is_immediate_constituent_of 'not' F iff H = F
proof
  thus H is_immediate_constituent_of 'not' F implies H = F
  proof
A1: now
      given H1 such that
A2:   'not' F = H '&' H1 or 'not' F = H1 '&' H or 'not' F = H 'or' H1
or 'not' F = H1 'or' H or 'not' F = H 'U' H1 or 'not' F = H1 'U' H or 'not' F =
      H 'R' H1 or 'not' F = H1 'R' H;
      ('not' F).1 = 0 by Th12;
      hence contradiction by A2,Th12;
    end;
A3: now
      assume
A4:   'not' F = 'X' H;
      ('not' F).1 = 0 by Th12;
      hence contradiction by A4,Th12;
    end;
    assume H is_immediate_constituent_of 'not' F;
    then
    'not' F = 'not' H or 'not' F = 'X' H or ex H1 st 'not' F = H '&' H1 or
'not' F = H1 '&' H or 'not' F = H 'or' H1 or 'not' F = H1 'or' H or 'not' F = H
    'U' H1 or 'not' F = H1 'U' H or 'not' F = H 'R' H1 or 'not' F = H1 'R' H;
    hence thesis by A3,A1,FINSEQ_1:33;
  end;
  thus thesis;
end;
