reserve I for non empty set;
reserve M for ManySortedSet of I;
reserve Y,x,y,i for set;
reserve r,r1,r2 for Real;

theorem Th13:
  for L be Lattice, L9 be SubLattice of L, X be Subset of L9, a be
  Element of L, a9 be Element of L9 st a = a9 holds X is_less_than a iff X
  is_less_than a9
proof
  let L be Lattice;
  let L9 be SubLattice of L;
  let X be Subset of L9;
  let a be Element of L;
  let a9 be Element of L9;
  assume
A1: a = a9;
  thus X is_less_than a implies X is_less_than a9
  proof
    assume
A2: X is_less_than a;
    now
      let q9 be Element of L9;
      the carrier of L9 c= the carrier of L by NAT_LAT:def 12;
      then reconsider q = q9 as Element of L;
      assume q9 in X;
      then
A3:   q [= a by A2;
      q9 "/\" a9 = q "/\" a by A1,Th11
        .= q9 by A3,LATTICES:4;
      hence q9 [= a9 by LATTICES:4;
    end;
    hence thesis;
  end;
  thus X is_less_than a9 implies X is_less_than a
  proof
    assume
A4: X is_less_than a9;
    now
      let q be Element of L;
      assume
A5:   q in X;
      then reconsider q9 = q as Element of L9;
A6:   q9 [= a9 by A4,A5;
      q "/\" a = q9 "/\" a9 by A1,Th11
        .= q by A6,LATTICES:4;
      hence q [= a by LATTICES:4;
    end;
    hence thesis;
  end;
end;
