reserve a,a1,a2,v,v1,v2,x for object;
reserve V,A for set;
reserve m,n for Nat;
reserve S,S1,S2 for FinSequence;

theorem Th13:
  m <> 0 & m <= n implies FNDSC(V,A).m c= FNDSC(V,A).n
  proof
    assume
A1: m <> 0;
    set S = FNDSC(V,A);
    defpred P[Nat] means m <= $1 implies S.m c= S.$1;
A2: P[0];
A3: for k being Nat st P[k] holds P[k+1]
    proof
      let k be Nat;
      assume
A4:   P[k];
      assume that
A5:   m <= k+1;
      per cases by A5,NAT_1:8;
      suppose m = k+1;
        hence thesis;
      end;
      suppose
A6:     m <= k;
        per cases;
        suppose k = 0;
          hence S.m c= S.(k+1) by A1,A6;
        end;
        suppose
A7:       k <> 0;
          defpred R[Nat] means $1 <> 0 implies S.$1 c= S.($1+1);
A8:       R[0];
A9:       for z being Nat st R[z] holds R[z+1]
          proof
            let z be Nat such that
A10:        R[z];
            per cases;
            suppose
A11:          z = 0;
A12:          S.1 = NDSS(V,A) by Th9;
              S.(1+1) = NDSS(V,A\/NDSS(V,A)) by Th10;
              hence thesis by A11,A12,Th7,XBOOLE_1:7;
            end;
            suppose z <> 0;
              then
A13:          A\/S.z c= A\/S.(z+1) by A10,XBOOLE_1:9;
A14:          S.(z+1) = NDSS(V,A\/S.z) by Def3;
              S.(z+1+1) = NDSS(V,A\/S.(z+1)) by Def3;
              hence thesis by A13,A14,Th7;
            end;
          end;
          for z being Nat holds R[z] from NAT_1:sch 2(A8,A9);
          then S.k c= S.(k+1) by A7;
          hence thesis by A4,A6;
        end;
      end;
    end;
    for k being Nat holds P[k] from NAT_1:sch 2(A2,A3);
    hence thesis;
  end;
