reserve A,A1,A2,B,C,D for Ordinal,
  X,Y for set,
  x,y,a,b,c for object,
  L,L1,L2,L3 for Sequence,
  f for Function;

theorem Th13:
  (for x st x in X holds x is Ordinal) implies meet X is Ordinal
proof
  assume
A1: for x st x in X holds x is Ordinal;
  now
    defpred P[Ordinal] means $1 in X;
    set x = the Element of X;
    assume
A2: X <> 0;
    then x is Ordinal by A1;
    then
A3: ex A st P[A] by A2;
    consider A such that
A4: P[A] & for B st P[B] holds A c= B from ORDINAL1:sch 1(A3);
    for x being object holds x in A iff for Y st Y in X holds x in Y
    proof
      let x be object;
      thus x in A implies for Y st Y in X holds x in Y
      proof
        assume
A5:     x in A;
        let Y;
        assume
A6:     Y in X;
        then reconsider B = Y as Ordinal by A1;
        A c= B by A4,A6;
        hence thesis by A5;
      end;
      assume for Y st Y in X holds x in Y;
      hence thesis by A4;
    end;
    hence thesis by A2,SETFAM_1:def 1;
  end;
  hence thesis by SETFAM_1:def 1;
end;
