
theorem Th13:
  for I being non empty set for A be PLS-yielding ManySortedSet of
I for i being Element of I for p being Point of A.i for L being Segre-like non
  trivial-yielding ManySortedSubset of Carrier A st i<>indx(L) holds L+*(i,{p})
  is Segre-like non trivial-yielding ManySortedSubset of Carrier A
proof
  let I be non empty set;
  let A be PLS-yielding ManySortedSet of I;
  let i be Element of I;
  let p be Point of A.i;
  let L be Segre-like non trivial-yielding ManySortedSubset of Carrier A;
A1: now
    let j be Element of I;
A2: dom L=I by PARTFUN1:def 2;
    assume
A3: j<>indx(L);
    per cases;
    suppose
      j=i;
      hence L+*(i,{p}).j is 1-element by A2,FUNCT_7:31;
    end;
    suppose
      j<>i;
      then L+*(i,{p}).j = L.j by FUNCT_7:32;
      hence L+*(i,{p}).j is 1-element by A3,PENCIL_1:12;
    end;
  end;
A4: L+*(i,{p}) c= Carrier A
  proof
    let a be object;
    assume
A5: a in I;
    then reconsider a1=a as Element of I;
A6: a1 in dom L by A5,PARTFUN1:def 2;
    per cases;
    suppose
A7:   a=i;
      then L+*(i,{p}).a1 = {p} by A6,FUNCT_7:31;
      then L+*(i,{p}).a1 c= [#](A.a1) by A7;
      hence thesis by Th7;
    end;
    suppose
A8:   a<>i;
A9:   L c= Carrier A by PBOOLE:def 18;
      L+*(i,{p}).a1 = L.a1 by A8,FUNCT_7:32;
      hence thesis by A9;
    end;
  end;
  assume i<>indx(L);
  then L+*(i,{p}).indx(L) = L.indx(L) by FUNCT_7:32;
  then
A10: L+*(i,{p}).indx(L) is non trivial by PENCIL_1:def 21;
  dom (L+*(i,{p})) = I by PARTFUN1:def 2;
  then L+*(i,{p}).indx(L) in rng (L+*(i,{p})) by FUNCT_1:3;
  hence thesis by A4,A1,A10,PBOOLE:def 18,PENCIL_1:def 16,def 20;
end;
