reserve n,m,k for Element of NAT,
  x,X for set,
  A1 for SetSequence of X,
  Si for SigmaField of X,
  XSeq for SetSequence of Si;
reserve Omega for non empty set,
  Sigma for SigmaField of Omega,
  ASeq for SetSequence of Sigma,
  P for Probability of Sigma;

theorem Th13:
  P is sigma_Measure of Sigma
proof
  set Z = Sigma;
  reconsider P1 = P as Function of Z,ExtREAL by FUNCT_2:7,NUMBERS:31;
  for x being ExtReal holds x in rng P1 implies 0. <= x
  proof
    let x be ExtReal;
    assume
A1: x in rng P1;
    dom P1 = Sigma by FUNCT_2:def 1;
    then consider y being object such that
A2: y in Sigma and
A3: P1.y = x by A1,FUNCT_1:def 3;
    reconsider y1=y as Event of Sigma by A2;
    0 <= P.y1 by PROB_1:def 8;
    hence thesis by A3;
  end;
  then
A4: rng P1 is nonnegative by SUPINF_2:def 9;
  for F being Sep_Sequence of Z holds SUM(P1 * F) = P1.(union rng F)
  proof
    let F be Sep_Sequence of Z;
    reconsider F2=F as disjoint_valued SetSequence of Sigma by Th2;
    for n being Nat holds (P * F2).n >= 0 by PROB_3:4;
    then
A5: P * F2 is nonnegative by RINFSUP1:def 3;
    Partial_Sums(P * F2) is convergent by PROB_3:45;
    then P * F2 is summable;
    then P.(Union F2) = Sum(P * F2) & Sum(P * F2) = SUM(P1 * F) by A5,Th12,
PROB_3:46;
    hence thesis by CARD_3:def 4;
  end;
  hence thesis by A4,MEASURE1:def 6,SUPINF_2:def 12;
end;
