reserve A for QC-alphabet;
reserve n,k,m for Nat;
reserve F,G,G9,H,H9 for Element of QC-WFF(A);
reserve t, t9, t99 for Element of dom tree_of_subformulae(F);
reserve x for set;

theorem Th13:
  t is_a_prefix_of t9 implies (tree_of_subformulae(F)).t9
  is_subformula_of (tree_of_subformulae(F)).t
proof
  assume t is_a_prefix_of t9;
  then consider r being FinSequence such that
A1: t9 = t^r by TREES_1:1;
  reconsider r as FinSequence of NAT by A1,FINSEQ_1:36;
  consider n such that
A2: n = len r;
  defpred P[set,object] means ex G being QC-formula of A,
  m,k1 being Nat, r1 being
  FinSequence st G = $2 & m = $1 & m+k1 = n+1 & r1 = r|Seg k1 & G = (
  tree_of_subformulae(F)).(t^r1);
A3: for k be Nat st k in Seg(n+1) ex x being object st P[k,x]
  proof
    let k be Nat;
    assume k in Seg(n+1);
    then k <= n+1 by FINSEQ_1:1;
    then consider k1 being Nat such that
A4: k+k1 = n+1 by NAT_1:10;
    reconsider k1 as Element of NAT by ORDINAL1:def 12;
    r|Seg k1 is FinSequence by FINSEQ_1:15;
    then consider r1 being FinSequence such that
A5: r1 = r|Seg k1;
    t^r1 in dom tree_of_subformulae(F)
    proof
      ex q being FinSequence st q = r|Seg k1 & q is_a_prefix_of r
       by TREES_9:32;
      hence thesis by A1,A5,FINSEQ_6:13,TREES_1:20;
    end;
    then reconsider t1 = t^r1 as Element of dom tree_of_subformulae(F);
    consider G being QC-formula of A such that
A6: G = (tree_of_subformulae(F)).t1;
    take G,G,k,k1,r1;
    thus thesis by A4,A5,A6;
  end;
  ex L being FinSequence st dom L = Seg(n+1) & for k be Nat st k in Seg(n
  +1) holds P[k,L.k] from FINSEQ_1:sch 1(A3);
  then consider L being FinSequence such that
A7: dom L = Seg (n+1) and
A8: for k be Nat st k in Seg (n+1) holds ex G being QC-formula of A, m,k1
being Nat, r1 being FinSequence st G = L.k & m = k & m+k1 = n+1 & r1 = r|Seg k1
  & G = (tree_of_subformulae(F)).(t^r1);
A9: len L = n+1 by A7,FINSEQ_1:def 3;
A10: for k st 1 <= k & k <= n+1 ex G being QC-formula of A,
k1 being Nat, r1
  being FinSequence st G = L.k & k+k1 = n+1 & r1 = r|Seg k1 & G = (
  tree_of_subformulae(F)).(t^r1)
  proof
    let k;
    assume 1 <= k & k <= n+1;
    then k in Seg (n+1) by FINSEQ_1:1;
    then
    ex G being QC-formula of A, m,k1 being Nat,
     r1 being FinSequence st G = L.k
& m = k & m+k1 = n+1 & r1 = r|Seg k1 & G = ( tree_of_subformulae(F)).(t^r1) by
A8;
    hence thesis;
  end;
A11: for k st 1 <= k & k < n+1 ex H1,G1 being Element of QC-WFF(A)
  st L.k = H1
  & L.(k+1) = G1 & H1 is_immediate_constituent_of G1
  proof
    let k;
    assume that
A12: 1 <= k and
A13: k < n+1;
    consider H1 being QC-formula of A, k1 being Nat,
     r1 being FinSequence such that
A14: H1 = L.k and
A15: k+k1 = n+1 and
A16: r1 = r|Seg k1 and
A17: H1 = (tree_of_subformulae(F)).(t^r1) by A10,A12,A13;
    1 <= k+1 & k+1 <= n+1 by A12,A13,NAT_1:13;
    then consider
    G1 being QC-formula of A,
      k2 being Nat, r2 being FinSequence such that
A18: G1 = L.(k+1) and
A19: (k+1)+k2 = n+1 and
A20: r2 = r|Seg k2 and
A21: G1 = (tree_of_subformulae(F)).(t^r2) by A10;
    reconsider k1,k2 as Element of NAT by ORDINAL1:def 12;
    k1+1 <= n+1 by A12,A15,XREAL_1:6;
    then k2+1 <= len r by A2,A15,A19,XREAL_1:6;
    then consider m being Element of NAT such that
A22: r1 = r2^<*m*> by A15,A16,A19,A20,TREES_9:33;
    t^r2 in dom tree_of_subformulae(F)
    proof
      ex q being FinSequence st q = r|Seg k2 & q is_a_prefix_of r
       by TREES_9:32;
      hence thesis by A1,A20,FINSEQ_6:13,TREES_1:20;
    end;
    then reconsider t2 = t^r2 as Element of dom tree_of_subformulae(F);
A23: t2^<*m*> = t^r1 by A22,FINSEQ_1:32;
    t2^<*m*> in dom tree_of_subformulae(F)
    proof
      ex q being FinSequence st q = r|Seg k1 & q is_a_prefix_of r
       by TREES_9:32;
      hence thesis by A1,A16,A23,FINSEQ_6:13,TREES_1:20;
    end;
    then H1 is_immediate_constituent_of G1 by A17,A21,A23,Th7;
    hence thesis by A14,A18;
  end;
A24: 0+1 <= n+1 by NAT_1:13;
  then consider
  G being QC-formula of A, k1 being Nat, r1 being FinSequence such that
A25: G = L.1 and
A26: 1+k1 = n+1 and
A27: r1 = r|Seg k1 and
A28: G = (tree_of_subformulae(F)).(t^r1) by A10;
A29: L.(n+1) = (tree_of_subformulae(F)).t
  proof
    consider G being QC-formula of A,
    k1 being Nat, r1 being FinSequence such that
A30: G = L.(n+1) and
A31: (n+1)+k1 = n+1 & r1 = r|Seg k1 and
A32: G = (tree_of_subformulae(F)).(t^r1) by A24,A10;
    r1 = {} by A31;
    hence thesis by A30,A32,FINSEQ_1:34;
  end;
  dom r = Seg k1 by A2,A26,FINSEQ_1:def 3;
  then t9 = t^r1 by A1,A27;
  hence thesis by A24,A9,A25,A28,A29,A11,QC_LANG2:def 20;
end;
