 reserve x for set,
         n,m,k for Nat,
         r for Real,
         V for RealLinearSpace,
         v,u,w,t for VECTOR of V,
         Av for finite Subset of V,
         Affv for finite affinely-independent Subset of V;
reserve pn for Point of TOP-REAL n,
        An for Subset of TOP-REAL n,
        Affn for affinely-independent Subset of TOP-REAL n,
        Ak for Subset of TOP-REAL k;
reserve EV for Enumeration of Affv,
        EN for Enumeration of Affn;

theorem Th13:
  for V be Abelian add-associative right_zeroed right_complementable
    non empty addLoopStr
  for A be finite Subset of V, E be Enumeration of A, v be Element of V
  holds E+(card A|->v) is Enumeration of (v+A)
proof
  let V be Abelian add-associative right_zeroed right_complementable non empty
addLoopStr;
  let A be finite Subset of V;
  let E be Enumeration of A;
  let v be Element of V;
  A1: rng E=A by Def1;
  then A2: len E=card A by FINSEQ_4:62;
  then reconsider e=E,cAv=card A|->v as Element of card A-tuples_on the carrier
of V by FINSEQ_2:92;
  A3: len(e+cAv)=card A by CARD_1:def 7;
  then A4: dom(e+cAv)=Seg card A by FINSEQ_1:def 3;
  A5: dom e=Seg card A by A2,FINSEQ_1:def 3;
  A6: rng(e+cAv)c=v+A
  proof
   let y be object;
   assume y in rng(e+cAv);
   then consider x be object such that
    A7: x in dom(e+cAv) and
    A8: (e+cAv).x=y by FUNCT_1:def 3;
   reconsider x as Element of NAT by A7;
   A9: e.x in rng e by A5,A4,A7,FUNCT_1:def 3;
   then reconsider Ex=e.x as Element of V;
   cAv.x=v by A4,A7,FINSEQ_2:57;
   then y=Ex+v by A7,A8,FVSUM_1:17;
   then y=v+Ex by RLVECT_1:def 2;
   then y in {v+w where w is Element of V:w in A} by A1,A9;
   hence thesis by RUSUB_4:def 8;
  end;
  v+A c=rng(e+cAv)
  proof
   let vA be object;
   assume vA in v+A;
   then vA in {v+a where a is Element of V:a in A} by RUSUB_4:def 8;
   then consider a be Element of V such that
    A10: vA=v+a and
    A11: a in A;
   consider x be object such that
    A12: x in dom E and
    A13: E.x=a by A1,A11,FUNCT_1:def 3;
   reconsider x as Element of NAT by A12;
   cAv.x=v by A5,A12,FINSEQ_2:57;
   then (e+cAv).x=a+v by A5,A4,A12,A13,FVSUM_1:17
    .=vA by A10,RLVECT_1:def 2;
   hence thesis by A5,A4,A12,FUNCT_1:def 3;
  end;
  then A14: v+A=rng(e+cAv) by A6;
  card A=card(v+A) by RLAFFIN1:7;
  then e+cAv is one-to-one by A3,A14,FINSEQ_4:62;
  hence thesis by A14,Def1;
 end;
