reserve x,y,X for set,
        r for Real,
        n,k for Nat;
reserve RLS for non empty RLSStruct,
        Kr,K1r,K2r for SimplicialComplexStr of RLS,
        V for RealLinearSpace,
        Kv for non void SimplicialComplex of V;

theorem Th13:
  for K be subset-closed SimplicialComplexStr of V
    for SF be Subset-Family of K st SF = Sub_of_Fin the topology of K
  holds Complex_of SF is SubdivisionStr of K
 proof
  let K be subset-closed SimplicialComplexStr of V;
  set TOP=the topology of K;
  let SF be Subset-Family of K such that
   A1: SF=Sub_of_Fin TOP;
  set C=Complex_of SF;
  [#]C=[#]K & [#]K c=the carrier of V by SIMPLEX0:def 9;
  then reconsider C as SimplicialComplexStr of V by SIMPLEX0:def 9;
  A2: the_family_of K is subset-closed;
  then A3: the topology of C=SF by A1,SIMPLEX0:7;
  C is SubdivisionStr of K
  proof
   thus|.K.|c=|.C.|
   proof
    let x be object;
    assume x in |.K.|;
    then consider S be Subset of K such that
     A4: S is simplex-like and
     A5: x in conv@S by Def3;
    reconsider S1=@S as non empty Subset of V by A5;
    x in {Sum(L) where L is Convex_Combination of S1:
    L in ConvexComb(V)} by A5,CONVEX3:5;
    then consider L be Convex_Combination of S1 such that
     A6: x=Sum L & L in ConvexComb(V);
    reconsider Carr=Carrier L as non empty Subset of V by CONVEX1:21;
    A7: Carr c=S by RLVECT_2:def 6;
    then reconsider Carr1=Carr as Subset of C by XBOOLE_1:1;
    S in TOP by A4;
    then Carr1 in TOP by A2,A7,CLASSES1:def 1;
    then Carr1 in the topology of C by A1,A3,COHSP_1:def 3;
    then A8: Carr1 is simplex-like;
    reconsider LC=L as Linear_Combination of Carr by RLVECT_2:def 6;
    LC is convex;
    then x in {Sum(M) where M is Convex_Combination of Carr:M in ConvexComb(V)}
by A6;
    then A9: x in conv Carr by CONVEX3:5;
    Carr=@Carr1;
    hence thesis by A8,A9,Def3;
   end;
   let A be Subset of C;
   reconsider B=A as Subset of K;
   assume A is simplex-like;
   then A in the topology of C;
   then A10: B is simplex-like by A1,A3;
   @A=@B;
   hence thesis by A10;
  end;
  hence thesis;
 end;
