reserve n   for Nat,
        r,s for Real,
        x,y for Element of REAL n,
        p,q for Point of TOP-REAL n,
        e   for Point of Euclid n;

theorem
  e = p implies
  the set of all OpenHypercube(e,1/m) where m is non zero Element of NAT =
  the set of all OpenHypercube(p,1/m) where m is non zero Element of NAT
  proof
    assume
A1: e = p;
A2: for m be non zero Element of NAT holds
    OpenHypercube(e,1/m) = OpenHypercube(p,1/m)
    proof
      let m be non zero Element of NAT;
      consider e0 be Point of Euclid n such that
A3:   p = e0 and
A4:   OpenHypercube(e0,1/m) = OpenHypercube(p,1/m) by TIETZE_2:def 1;
      thus thesis by A1,A3,A4;
    end;
    set XE = the set of all OpenHypercube(e,1/m) where
              m is non zero Element of NAT;
    set XTR = the set of all OpenHypercube(p,1/m) where
              m is non zero Element of NAT;
    thus XE c= XTR
    proof
      let x be object;
      assume x in XE;
      then consider me be non zero Element of NAT such that
A6:   x = OpenHypercube(e,1/me);
      x = OpenHypercube(p,1/me) by A6,A2;
      hence thesis;
    end;
      let x be object;
      assume x in XTR;
      then consider mtr be non zero Element of NAT such that
A7:   x = OpenHypercube(p,1/mtr);
      x = OpenHypercube(e,1/mtr) by A7,A2;
      hence thesis;
  end;
