 reserve A,B,O for Ordinal,
      n,m for Nat,
      a,b,o for object,
      x,y,z for Surreal,
      X,Y,Z for set,
      Inv,I1,I2 for Function;

theorem Th13:
  Union divR(x,Inv)
      = divset(Union divL(x,Inv),x,L_x,Inv)\/
        divset(Union divR(x,Inv),x,R_x,Inv)
proof
  defpred P[Nat] means
  divR(x,Inv).$1 c= divset(Union divL(x,Inv),x,L_x,Inv)\/
  divset(Union divR(x,Inv),x,R_x,Inv);
  divR(x,Inv).0 = {} by Th1;
  then
A1: P[0] by XBOOLE_1:2;
A2: P[n] implies P[n+1]
  proof
    assume
A3: P[n];
    let o;
    assume
A4: o in divR(x,Inv).(n+1);
    divR(x,Inv).(n+1) = divR(x,Inv).n \/
    divset(divL(x,Inv).n,x,L_x,Inv) \/ divset(divR(x,Inv).n,x,R_x,Inv)
      by Th6;
    then o in divR(x,Inv).n \/
    divset(divL(x,Inv).n,x,L_x,Inv) or o in divset(divR(x,Inv).n,x,R_x,Inv)
      by A4,XBOOLE_0:def 3;
    then per cases by XBOOLE_0:def 3;
    suppose o in divR(x,Inv).n;
      hence thesis by A3;
    end;
    suppose
A5:   o in divset(divL(x,Inv).n,x,L_x,Inv);
      divset(divL(x,Inv).n,x,L_x,Inv) c=
      divset(Union divL(x,Inv),x,L_x,Inv) by Th11,ABCMIZ_1:1;
      hence thesis by A5,XBOOLE_0:def 3;
    end;
    suppose
A6:   o in divset(divR(x,Inv).n,x,R_x,Inv);
      divset(divR(x,Inv).n,x,R_x,Inv) c=
      divset(Union divR(x,Inv),x,R_x,Inv) by Th11,ABCMIZ_1:1;
      hence thesis by A6,XBOOLE_0:def 3;
    end;
  end;
A7: P[n] from NAT_1:sch 2(A1,A2);
  thus Union divR(x,Inv)
  c= divset(Union divL(x,Inv),x,L_x,Inv)\/divset(Union divR(x,Inv),x,R_x,Inv)
  proof
    let o;
    assume o in Union divR(x,Inv);
    then consider n be object such that
A8: n in dom divR(x,Inv) & o in divR(x,Inv).n by CARD_5:2;
    n in NAT by A8,Def6;
    then reconsider n as Nat;
    divR(x,Inv).n c= divset(Union divL(x,Inv),x,L_x,Inv)\/
    divset(Union divR(x,Inv),x,R_x,Inv) by A7;
    hence thesis by A8;
  end;
A9: divset(Union divL(x,Inv),x,L_x,Inv) c= Union divR(x,Inv)
  proof
    let o;
    assume o in divset(Union divL(x,Inv),x,L_x,Inv);
    then consider l be object such that
A10: l in Union divL(x,Inv) & o in divs(l,x,L_x,Inv) by Def3;
    consider n be object such that
A11: n in dom divL(x,Inv) & l in divL(x,Inv).n by A10,CARD_5:2;
    n in NAT by A11,Def5;
    then reconsider n as Nat;
    o in divset(divL(x,Inv).n,x,L_x,Inv) by A10,A11,Def3;
    then o in  divR(x,Inv).n \/ divset(divL(x,Inv).n,x,L_x,Inv)
    by XBOOLE_0:def 3;
    then o in divR(x,Inv).n \/
    divset(divL(x,Inv).n,x,L_x,Inv) \/
    divset(divR(x,Inv).n,x,R_x,Inv) by XBOOLE_0:def 3;
    then
A12: o in divR(x,Inv).(n+1) by Th6;
    n+1 in NAT;
    then n+1 in dom divR(x,Inv) by Def6;
    hence thesis by A12,CARD_5:2;
  end;
  divset(Union divR(x,Inv),x,R_x,Inv) c= Union divR(x,Inv)
  proof
    let o;
    assume o in divset(Union divR(x,Inv),x,R_x,Inv);
    then consider l be object such that
A13: l in Union divR(x,Inv) & o in divs(l,x,R_x,Inv) by Def3;
    consider n be object such that
A14: n in dom divR(x,Inv) & l in divR(x,Inv).n by A13,CARD_5:2;
    n in NAT by A14,Def6;
    then reconsider n as Nat;
    o in divset(divR(x,Inv).n,x,R_x,Inv) by A13,A14,Def3;
    then o in divR(x,Inv).n \/
    divset(divL(x,Inv).n,x,L_x,Inv) \/
    divset(divR(x,Inv).n,x,R_x,Inv) by XBOOLE_0:def 3;
    then
A15: o in divR(x,Inv).(n+1) by Th6;
    n+1 in NAT;
    then n+1 in dom divR(x,Inv) by Def6;
    hence thesis by A15,CARD_5:2;
  end;
  hence thesis by A9,XBOOLE_1:8;
end;
