reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th13:
  for P, Q being Subset of T holds P is bounded & Q is bounded
  implies P \/ Q is bounded
proof
  let P, Q be Subset of T;
  assume that
A1: P is bounded and
A2: Q is bounded;
  per cases;
  suppose
    P = {};
    hence thesis by A2;
  end;
  suppose
A3: P <> {};
    now
      per cases;
      suppose
        Q = {};
        hence thesis by A1;
      end;
      suppose
        Q <> {};
        then consider s be Real, d be Element of T such that
A4:     0<s and
        d in Q and
A5:     for z being Point of T st z in Q holds dist(d,z)<=s by A2,Th10;
        consider r,t1 such that
A6:     0<r and
A7:     t1 in P and
A8:     for z being Point of T st z in P holds dist(t1,z)<=r by A1,A3,Th10;
        set t = r+s+dist(t1,d);
A9:     0<=dist(t1,d) by METRIC_1:5;
        then
A10:    r<r+(dist(t1,d)+s) by A4,XREAL_1:29;
        ex t being Real,t1 st 0<t & t1 in P \/ Q & for z being Point of T
        st z in P \/ Q holds dist(t1,z)<=t
        proof reconsider t as Real;
          take t,t1;
          thus 0<t by A6,A4,A9;
          thus t1 in P \/ Q by A7,XBOOLE_0:def 3;
          let z be Point of T;
          assume z in P \/ Q;
          then
A11:      z in P or z in Q by XBOOLE_0:def 3;
          now
            per cases by A8,A5,A11;
            suppose
              dist(t1,z)<=r;
              hence thesis by A10,XXREAL_0:2;
            end;
            suppose
              dist(d,z)<=s;
              then dist(t1,z)<=dist(t1,d)+dist(d,z) & dist(t1,d)+dist(d,z)<=
              dist(t1,d)+s by METRIC_1:4,XREAL_1:7;
              then
A12:          dist(t1,z)<=dist(t1,d)+s by XXREAL_0:2;
              dist(t1,d)+s<=r+(dist(t1,d)+s) by A6,XREAL_1:29;
              hence thesis by A12,XXREAL_0:2;
            end;
          end;
          hence thesis;
        end;
        hence thesis by Th10;
      end;
    end;
    hence thesis;
  end;
end;
