reserve r for Real;
reserve a, b for Real;
reserve T for non empty TopSpace;
reserve A for non empty SubSpace of T;
reserve P,Q for Subset of T,
  p for Point of T;
reserve M for non empty MetrSpace,
  p for Point of M;
reserve A for non empty SubSpace of M;
reserve F,G for Subset-Family of M;

theorem Th13:
  TopSpaceMetr(A) is SubSpace of TopSpaceMetr(M)
proof
  set T = TopSpaceMetr M, R = TopSpaceMetr A;
  thus [#](R) c= [#](T) by Def1;
  let P be Subset of R;
  thus P in the topology of R implies ex Q being Subset of T st Q in the
  topology of T & P = Q /\ [#](R)
  proof
    set QQ = {Ball(x,r) where x is Point of M, r is Real:
     x in P & r > 0 & Ball(x,r) /\ the carrier of A c= P};
    for X being set st X in QQ holds X c= the carrier of M
    proof
      let X be set;
      assume X in QQ;
      then
      ex x being Point of M, r being Real
        st X = Ball(x,r) & x in P & r > 0 & Ball(x,r) /\ the carrier of A c= P;
      hence thesis;
    end;
    then reconsider Q = union QQ as Subset of M by ZFMISC_1:76;
    reconsider Q9 = Q as Subset of T;
    assume P in the topology of R;
    then
A1: P in Family_open_set A;
A2: P c= Q9 /\ [#](R)
    proof
      reconsider P9 = P as Subset of A;
      let a be object;
      assume
A3:   a in P;
      then reconsider x = a as Point of A;
      reconsider x9 = x as Point of M by Th8;
      consider r such that
A4:   r > 0 and
A5:   Ball(x,r) c= P9 by A1,A3,PCOMPS_1:def 4;
      Ball(x,r) = Ball(x9,r) /\ the carrier of A by Th9;
      then
A6:   Ball(x9,r) in QQ by A3,A4,A5;
      x9 in Ball(x9,r) by A4,TBSP_1:11;
      then a in Q9 by A6,TARSKI:def 4;
      hence thesis by A3,XBOOLE_0:def 4;
    end;
    take Q9;
    for x being Point of M st x in Q ex r st r > 0 & Ball(x,r) c= Q
    proof
      let x be Point of M;
      assume x in Q;
      then consider Y being set such that
A7:   x in Y and
A8:   Y in QQ by TARSKI:def 4;
      consider x9 being Point of M, r being Real such that
A9:  Y = Ball(x9,r) and
      x9 in P and
      r > 0 and
      Ball(x9,r) /\ the carrier of A c= P by A8;
      consider p being Real such that
A10:  p > 0 and
A11:  Ball(x,p) c= Ball(x9,r) by A7,A9,PCOMPS_1:27;
      take p;
      thus p > 0 by A10;
      Y c= Q by A8,ZFMISC_1:74;
      hence thesis by A9,A11;
    end;
    then Q in Family_open_set M by PCOMPS_1:def 4;
    hence Q9 in the topology of T;
    Q9 /\ [#](R) c= P
    proof
      let a be object;
      assume
A12:  a in Q9 /\ [#](R);
      then a in Q9 by XBOOLE_0:def 4;
      then consider Y being set such that
A13:  a in Y and
A14:  Y in QQ by TARSKI:def 4;
      consider x being Point of M, r being Real such that
A15:  Y = Ball(x,r) and
      x in P and
      r > 0 and
A16:  Ball(x,r) /\ the carrier of A c= P by A14;
      a in Ball(x,r) /\ the carrier of A by A12,A13,A15,XBOOLE_0:def 4;
      hence thesis by A16;
    end;
    hence P = Q9 /\ [#](R) by A2,XBOOLE_0:def 10;
  end;
  reconsider P9 = P as Subset of A;
  given Q being Subset of T such that
A17: Q in the topology of T and
A18: P = Q /\ [#](R);
  reconsider Q9 = Q as Subset of M;
  for p being Point of A st p in P9 ex r st r>0 & Ball(p,r) c= P9
  proof
    let p be Point of A;
    reconsider p9 = p as Point of M by Th8;
    assume p in P9;
    then
A19: p9 in Q9 by A18,XBOOLE_0:def 4;
    Q9 in Family_open_set M by A17;
    then consider r such that
A20: r>0 and
A21: Ball(p9,r) c= Q9 by A19,PCOMPS_1:def 4;
    Ball(p,r) = Ball(p9,r) /\ the carrier of A by Th9;
    then Ball(p,r) c= Q /\ the carrier of A by A21,XBOOLE_1:26;
    then Ball(p,r) c= Q /\ the carrier of R;
    hence thesis by A18,A20;
  end;
  then P in Family_open_set A by PCOMPS_1:def 4;
  hence thesis;
end;
