reserve E,V for set, G,G1,G2 for _Graph, c,c1,c2 for Cardinal, n for Nat;
reserve f for VColoring of G;
reserve g for EColoring of G;
reserve t for TColoring of G;

theorem Th142:
  for e being object, v,w,u being Vertex of G2, G1 being addEdge of G2,v,e,w
  for t being TColoring of G2, x,y being object st not e in the_Edges_of G2
  holds [t_V +* (u .--> x), t_E +* (e .--> y)] is TColoring of G1
proof
  let e be object, v,w,u be Vertex of G2, G1 be addEdge of G2,v,e,w;
  let t be TColoring of G2, x,y be object;
  assume not e in the_Edges_of G2;
  then reconsider t9 = [t_V, t_E +* (e .--> y)] as TColoring of G1 by Th141;
  A1: u is Vertex of G1 by GLIB_006:68;
  dom(t_V +* (u .--> x)) = dom t9_V \/ dom(u .--> x) by FUNCT_4:def 1
    .= the_Vertices_of G1 \/ dom(u .--> x) by PARTFUN1:def 2
    .= the_Vertices_of G1 \/ dom{[u,x]} by FUNCT_4:82
    .= the_Vertices_of G1 \/ {u} by RELAT_1:9
    .= the_Vertices_of G1 by A1, ZFMISC_1:40;
  then t9_V +* (u .--> x) is VColoring of G1 by RELAT_1:def 18, PARTFUN1:def 2;
  then [t9_V +* (u .--> x), t9_E] is TColoring of G1 by Def9;
  hence thesis;
end;
