reserve G for _Graph;
reserve G2 for _Graph, G1 for Supergraph of G2;
reserve V for set;
reserve v for object;

theorem Th153:
  for G2 for v1, e being object, v2 being Vertex of G2
  for G1 being addAdjVertex of G2,v1,e,v2
  st not e in the_Edges_of G2 & not v1 in the_Vertices_of G2
    & G2 is non _trivial
  holds G1 is non complete
proof
  let G2;
  let v1,e be object, v2 be Vertex of G2;
  let G1 be addAdjVertex of G2,v1,e,v2;
  assume that
    A1: not e in the_Edges_of G2 & not v1 in the_Vertices_of G2 and
    A2: G2 is non _trivial;
  ex u,v being Vertex of G1 st u <> v & not u, v are_adjacent
  proof
    consider u1,u2 being Vertex of G2 such that
      A3: u1 <> u2 by A2, GLIB_000:21;
    A4: u1 <> v1 & u2 <> v1 by A1;
    reconsider u1,u2 as Vertex of G1 by Th72;
    reconsider v1 as Vertex of G1 by A1, Th134;
    per cases;
    suppose A5: u1 <> v2;
      take v1,u1;
      not ex e1 being object st e1 Joins v1,u1,G1 by A1, A5, Th138;
      hence thesis by A4, CHORD:def 3;
    end;
    suppose A6: u2 <> v2;
      take v1,u2;
      not ex e1 being object st e1 Joins v1,u2,G1 by A1, A6, Th138;
      hence thesis by A4, CHORD:def 3;
    end;
    suppose u1=v2 & u2=v2;
      hence thesis by A3;
    end;
  end;
  hence thesis by CHORD:def 6;
end;
