 reserve i,n for Nat;
 reserve r for Real;
 reserve ra for Element of F_Real;
 reserve a,b,c for non zero Element of F_Real;
 reserve u,v for Element of TOP-REAL 3;
 reserve p1 for FinSequence of (1-tuples_on REAL);
 reserve pf,uf for FinSequence of F_Real;
 reserve N for Matrix of 3,F_Real;
 reserve K for Field;
 reserve k for Element of K;
 reserve N,N1,N2 for invertible Matrix of 3,F_Real;
 reserve P,P1,P2,P3 for Point of ProjectiveSpace TOP-REAL 3;

theorem Th15:
  (homography(1.(F_Real,3))).P = P
  proof
    consider u,v being Element of TOP-REAL 3,
    uf being FinSequence of F_Real,
    p being FinSequence of (1-tuples_on REAL) such that
A1: P = Dir u and
    u is not zero and
A3: u = uf and
A4: p = 1.(F_Real,3) * uf and
A5: v = M2F p and
    v is not zero and
A7: (homography(1.(F_Real,3))).P = Dir v by ANPROJ_8:def 4;
    u in TOP-REAL 3; then
A8: uf in REAL 3 by A3,EUCLID:22; then
A9: len uf = 3 by EUCLID_8:50;
A10: 1.(F_Real,3) * uf = 1.(F_Real,3) * <*uf*>@ by LAPLACE:def 9
                      .= <*uf*>@ by A8,EUCLID_8:50,ANPROJ_8:99;
    reconsider ur = uf as FinSequence of REAL;
    p = F2M ur by A4,A8,A10,EUCLID_8:50,ANPROJ_8:88;
    hence thesis by A1,A3,A5,A7,A9,ANPROJ_8:86;
  end;
