reserve n for Element of NAT,
  a, r for Real,
  x for Point of TOP-REAL n;
reserve n for Element of NAT,
  r for non negative Real,
  s, t, x for Point of TOP-REAL n;
reserve n for non zero Element of NAT,
  s, t, o for Point of TOP-REAL n;

theorem Th14:
  for r being non negative Real, o being Point of
  TOP-REAL 2, f being continuous Function of Tdisk(o,r), Tdisk(o,r) holds f
  is with_fixpoint
proof
  let r be non negative Real, o be Point of TOP-REAL 2, f be
  continuous Function of Tdisk(o,r), Tdisk(o,r);
A1: the carrier of Tcircle(o,r) = Sphere(o,r) by TOPREALB:9;
A2: the carrier of Tdisk(o,r) = cl_Ball(o,r) by Th3;
  per cases;
  suppose
    r is positive;
    then reconsider r as positive Real;
    Sphere(o,r) c= cl_Ball(o,r) by TOPREAL9:17;
    then reconsider
    Y = Tcircle(o,r) as non empty SubSpace of Tdisk(o,r) by A1,A2,TSEP_1:4;
    reconsider g = BR-map(f) as Function of Tdisk(o,r),Y;
A3: not Y is_a_retract_of Tdisk(o,r) by Th10;
    assume
A4: f is without_fixpoints;
A5: g is being_a_retraction
    by A4,Th11;
    g is continuous by A4,Th13;
    hence contradiction by A3,A5;
  end;
  suppose
    r is non positive;
    then reconsider r as non negative non positive Real;
    take o;
A6: cl_Ball(o,r) = {o} by Th2;
    dom f = the carrier of Tdisk(o,r) by FUNCT_2:def 1;
    hence o in dom f by A2,A6,TARSKI:def 1;
    then f.o in rng f by FUNCT_1:def 3;
    hence thesis by A2,A6,TARSKI:def 1;
  end;
end;
