
theorem Th14:
  for x1,x2,x3,x4,x5 being object
  holds rng <*x1,x2,x3,x4,x5*> = {x1, x2,x3,x4,x5}
proof
  let x1,x2,x3,x4,x5 be object;
  for y being object holds y in {x1,x2,x3,x4,x5} iff
 ex x being object st x in
  dom <*x1,x2,x3,x4,x5*> & y = <*x1,x2,x3,x4,x5*>.x
  proof
    let y be object;
    thus y in {x1,x2,x3,x4,x5} implies
    ex x being object st x in dom <*x1,x2,x3,
    x4,x5*> & y = <*x1,x2,x3,x4,x5*>.x
    proof
A1:   dom <*x1,x2,x3,x4,x5*> = {1,2,3,4,5} by FINSEQ_1:89,FINSEQ_3:3;
      assume
A2:   y in {x1,x2,x3,x4,x5};
      per cases by A2,ENUMSET1:def 3;
      suppose
A3:     y=x1;
        take 1;
        thus 1 in dom <*x1,x2,x3,x4,x5*> by A1,ENUMSET1:def 3;
        thus thesis by A3;
      end;
      suppose
A4:     y=x2;
        take 2;
        thus 2 in dom <*x1,x2,x3,x4,x5*> by A1,ENUMSET1:def 3;
        thus thesis by A4;
      end;
      suppose
A5:     y=x3;
        take 3;
        thus 3 in dom <*x1,x2,x3,x4,x5*> by A1,ENUMSET1:def 3;
        thus thesis by A5;
      end;
      suppose
A6:     y=x4;
        take 4;
        thus 4 in dom <*x1,x2,x3,x4,x5*> by A1,ENUMSET1:def 3;
        thus thesis by A6;
      end;
      suppose
A7:     y=x5;
        take 5;
        thus 5 in dom <*x1,x2,x3,x4,x5*> by A1,ENUMSET1:def 3;
        thus thesis by A7;
      end;
    end;
    given x being object such that
A8: x in dom <*x1,x2,x3,x4,x5*> and
A9: y = <*x1,x2,x3,x4,x5*>.x;
    x in Seg 5 by A8,FINSEQ_1:89;
    then x=1 or x=2 or x=3 or x=4 or x=5 by ENUMSET1:def 3,FINSEQ_3:3;
    then
    <*x1,x2,x3,x4,x5*>.x = x1 or <*x1,x2,x3,x4,x5*>.x = x2 or <*x1,x2,x3,
    x4,x5*>.x = x3 or <*x1,x2,x3,x4,x5*>.x = x4 or <*x1,x2,x3,x4,x5*>.x = x5;
    hence thesis by A9,ENUMSET1:def 3;
  end;
  hence thesis by FUNCT_1:def 3;
end;
