reserve i, x, I for set,
  A, B, M for ManySortedSet of I,
  f, f1 for Function;
reserve SF, SG for SubsetFamily of M;
reserve E, T for Element of Bool M;

theorem Th14:
  SF is non empty implies for i st i in I holds |:SF:|.i = { x.i
  where x is Element of Bool M : x in SF }
proof
A1: dom |:SF:| = I by PARTFUN1:def 2;
  assume
A2: SF is non empty;
  then consider A being non empty functional set such that
A3: A = SF and
  dom |.SF.| = meet the set of all  dom x where x is Element of A  and
A4: for i st i in dom |.SF.| holds |.SF.|.i = the set of all
 x.i where x is Element
  of A  by Def2;
  let i such that
A5: i in I;
  set K = { x.i where x is Element of Bool M : x in SF }, N = the set of all
 x.i where x is
  Element of A ;
A6: K = N
  proof
    thus K c= N
    proof
      let q be object;
      assume q in K;
      then ex x being Element of Bool M st q = x.i & x in SF;
      hence thesis by A3;
    end;
    let q be object;
    assume q in N;
    then consider x being Element of A such that
A7: q = x.i;
    x in SF by A3;
    hence thesis by A7;
  end;
  |:SF:| = |.SF.| by A2,Def3;
  hence thesis by A4,A5,A1,A6;
end;
