
theorem Th13:
  for S be non void non empty ManySortedSign, MA be strict
  non-empty MSAlgebra over S holds SubSort MA is absolutely-multiplicative
  SubsetFamily of the Sorts of MA
proof
  let S be non void non empty ManySortedSign, MA be strict non-empty MSAlgebra
  over S;
  SubSort MA c= Bool the Sorts of MA
  proof
    let x be object;
    assume x in SubSort MA;
    then x is ManySortedSubset of the Sorts of MA by MSUALG_2:def 11;
    hence thesis by CLOSURE2:def 1;
  end;
  then reconsider SUBMA = SubSort MA as SubsetFamily of the Sorts of MA;
  for F be SubsetFamily of the Sorts of MA st F c= SUBMA holds meet |:F:|
  in SUBMA
  proof
    set M = bool (Union (the Sorts of MA));
    set I = the carrier of S;
    let F be SubsetFamily of the Sorts of MA such that
A1: F c= SUBMA;
    set x = meet |:F:|;
A2: dom x = I by PARTFUN1:def 2;
    rng x c= M
    proof
      let u be object;
       reconsider uu=u as set by TARSKI:1;
      assume u in rng x;
      then consider i be object such that
A3:   i in dom x and
A4:   u = x.i by FUNCT_1:def 3;
      dom (the Sorts of MA) = I by PARTFUN1:def 2;
      then (the Sorts of MA).i in rng (the Sorts of MA) by A2,A3,FUNCT_1:def 3;
      then
A5:   (the Sorts of MA).i c= union rng (the Sorts of MA) by ZFMISC_1:74;
      ex Q be Subset-Family of (the Sorts of MA).i st Q = |:F:|. i & u =
      Intersect Q by A2,A3,A4,MSSUBFAM:def 1;
      then uu c= union rng (the Sorts of MA) by A5;
      then u in bool (union rng (the Sorts of MA));
      hence thesis by CARD_3:def 4;
    end;
    then
A6: x in Funcs ( I, M) by A2,FUNCT_2:def 2;
    reconsider x as MSSubset of MA;
    for B be MSSubset of MA st B = x holds B is opers_closed by A1,Th3;
    hence thesis by A6,MSUALG_2:def 11;
  end;
  hence thesis by CLOSURE2:def 7;
end;
