reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;

theorem Th14:
  for V being ComplexLinearSpace, v being VECTOR of V, l being
  C_Linear_Combination of {v} holds Sum l = l.v * v
proof
  let V be ComplexLinearSpace;
  let v be VECTOR of V;
  let l be C_Linear_Combination of {v};
A1: Carrier l c= {v} by Def4;
  per cases by A1,ZFMISC_1:33;
  suppose
    Carrier l = {};
    then
A2: l = ZeroCLC V by Def3;
    hence Sum l = 0.V by Th11
      .= 0c * v by CLVECT_1:1
      .= l.v * v by A2,Th2;
  end;
  suppose
    Carrier l = {v};
    then consider F being FinSequence of the carrier of V such that
A3: F is one-to-one & rng F = {v} and
A4: Sum l = Sum(l (#) F) by Def6;
    F = <* v *> by A3,FINSEQ_3:97;
    then l (#) F = <* l.v * v *> by Th8;
    hence thesis by A4,RLVECT_1:44;
  end;
end;
