 reserve n,m,i,p for Nat,
         h,k,r,r1,r2,x,x0,x1,x2,x3 for Real;
 reserve f,f1,f2,g for Function of REAL,REAL;

theorem
  x0 in dom sec & x1 in dom sec implies
  [!sec(#)sec,x0,x1!] = 4*(sin(x0+x1)*sin(x0-x1))
  /((cos(x0+x1)+cos(x0-x1))^2*(x0-x1))
proof
  assume
A1:x0 in dom sec & x1 in dom sec;
A2:cos.x0<>0 & cos.x1<>0 by A1,RFUNCT_1:3;
  [!sec(#)sec,x0,x1!] = (sec.x0*sec.x0-(sec(#)sec).x1)/(x0-x1) by VALUED_1:5
    .= (sec.x0*sec.x0-sec.x1*sec.x1)/(x0-x1) by VALUED_1:5
    .= ((cos.x0)"*sec.x0-sec.x1*sec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((cos.x0)"*(cos.x0)"-sec.x1*sec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((cos.x0)"*(cos.x0)"-(cos.x1)"*sec.x1)/(x0-x1) by A1,RFUNCT_1:def 2
    .= (((cos.x0)")^2-((cos.x1)")^2)/(x0-x1) by A1,RFUNCT_1:def 2
    .= ((1/cos.x0-1/cos.x1)*(1/cos.x0+1/cos.x1))/(x0-x1)
    .= (((1*cos.x1-1*cos.x0)/(cos.x0*cos.x1))*(1/cos.x0+1/cos.x1))/(x0-x1)
                                                       by A2,XCMPLX_1:130
    .= (((cos.x1-cos.x0)/(cos.x0*cos.x1))*((cos.x1+cos.x0)/(cos.x0*cos.x1)))
       /(x0-x1) by A2,XCMPLX_1:116
    .= (((cos.x1-cos.x0)*(cos.x1+cos.x0))/((cos.x0*cos.x1)*(cos.x0*cos.x1)))
       /(x0-x1) by XCMPLX_1:76
    .= ((cos(x1)*cos(x1)-cos(x0)*cos(x0))/((cos(x0)*cos(x1))^2))/(x0-x1)
    .= ((sin(x0+x1)*sin(x0-x1))/((cos(x0)*cos(x1))^2))/(x0-x1)
                                                              by SIN_COS4:38
    .= ((sin(x0+x1)*sin(x0-x1))
       /(((1/2)*(cos(x0+x1)+cos(x0-x1)))^2))/(x0-x1) by SIN_COS4:32
    .= (1*(sin(x0+x1)*sin(x0-x1))
       /((1/4)*(cos(x0+x1)+cos(x0-x1))^2))/(x0-x1)
    .= ((1/(1/4))*((sin(x0+x1)*sin(x0-x1))
       /(cos(x0+x1)+cos(x0-x1))^2))/(x0-x1) by XCMPLX_1:76
    .= (4*(sin(x0+x1)*sin(x0-x1)))/(cos(x0+x1)+cos(x0-x1))^2/(x0-x1)
    .= 4*(sin(x0+x1)*sin(x0-x1))/((cos(x0+x1)+cos(x0-x1))^2*(x0-x1))
                                                     by XCMPLX_1:78;
  hence thesis;
end;
