 reserve n,k for Nat;
 reserve L for comRing;
 reserve R for domRing;
 reserve x0 for positive Real;

theorem
  for g be Polynomial of F_Rat st deg g >= 2 & @g is irreducible holds
    g.0 <> 0.F_Rat
    proof
      set PRat = (Polynom-Ring F_Rat);
      let g be Polynomial of F_Rat;
      assume
A1:   deg g >= 2 & @g is irreducible; then
      g is non zero Polynomial of F_Rat; then
      NormPolynomial(g) is monic; then
A4:   NormPolynomial(@g) is monic;
A5:   NormPolynomial(@g) is irreducible by A1,RING_4:28;
reconsider g1 = NormPolynomial(@g) as Polynomial of F_Rat;
A6:   @g1 is irreducible by A5;
      deg g1 = deg g by REALALG3:11; then
A8:   deg g1 >= 2 by A1;
A9:   g1.0 <> 0.F_Rat
      proof
        assume g1.0 = 0.F_Rat; then
        eval(g1,0.F_Rat) = 0.F_Rat by POLYNOM5:31; then
A12:    @g1 = @(<%-0.F_Rat,1.F_Rat%>*'poly_quotient(g1,0.F_Rat))
        by POLYNOM5:def 7,UPROOTS:50
        .= (@<%-0.F_Rat,1.F_Rat%>)* (@poly_quotient(g1,0.F_Rat))
        by POLYNOM3:def 10;
        @<%-0.F_Rat,1.F_Rat%> divides @g1 by A12,GCD_1:def 1; then
A14:    (@<%-0.F_Rat,1.F_Rat%> is Unit of PRat or
        @<%-0.F_Rat,1.F_Rat%> is_associated_to @g1) by A6,RING_2:def 9;
        deg <%-0.F_Rat,1.F_Rat %> = 2 - 1 by POLYNOM5:40 .= 1; then
A16:    deg <%-0.F_Rat,1.F_Rat %> = 1;
        g1 is monic by A4; then
        deg g1 = 1 by RING_4:30,37,A14,A16;
        hence contradiction by A8;
      end;
reconsider g0 = g as non zero Element of the carrier of PRat by A1;
      NormPolynomial (@g) = (LC g0)" * g0 by RING_4:23; then
      g1.0 = (LC g0)" * g.0 by POLYNOM5:def 4; then
      g.0 <> 0.F_Rat by A9;
      hence thesis;
   end;
