reserve x for Real,

  Z for open Subset of REAL;

theorem
  Z c= dom (cos (#) tan) implies (cos (#) tan) is_differentiable_on Z &
  for x st x in Z holds((cos (#) tan)`|Z).x = -(sin.x)^2/cos.x+1/cos.x
proof
A1: for x st x in Z holds cos is_differentiable_in x by SIN_COS:63;
  assume
A2: Z c= dom (cos (#) tan);
  then
A3: Z c= dom cos /\ dom tan by VALUED_1:def 4;
  then
A4: Z c= dom tan by XBOOLE_1:18;
  for x st x in Z holds tan is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then cos.x <> 0 by A4,FDIFF_8:1;
    hence thesis by FDIFF_7:46;
  end;
  then
A5: tan is_differentiable_on Z by A4,FDIFF_1:9;
  Z c= dom cos by A3,XBOOLE_1:18;
  then
A6: cos is_differentiable_on Z by A1,FDIFF_1:9;
A7: for x st x in Z holds diff(tan, x)=1/(cos.x)^2
  proof
    let x;
    assume x in Z;
    then cos.x<>0 by A4,FDIFF_8:1;
    hence thesis by FDIFF_7:46;
  end;
  for x st x in Z holds((cos (#) tan)`|Z).x = -(sin.x)^2/cos.x+1/cos.x
  proof
    let x;
    assume
A8: x in Z;
    then ((cos (#) tan)`|Z).x= diff(cos,x)*tan.x+cos.x*diff(tan,x) by A2,A5,A6,
FDIFF_1:21
      .=tan.x*(-sin.x)+cos.x*diff(tan,x) by SIN_COS:63
      .=tan.x*(-sin.x)+cos.x*(1/(cos.x)^2) by A7,A8
      .=(sin.x/cos.x)*(-sin.x/1)+cos.x/(cos.x)^2 by A4,A8,RFUNCT_1:def 1
      .=-(sin.x)^2/cos.x+cos.x/cos.x/cos.x by XCMPLX_1:78
      .=-(sin.x)^2/cos.x+1/cos.x by A4,A8,FDIFF_8:1,XCMPLX_1:60;
    hence thesis;
  end;
  hence thesis by A2,A5,A6,FDIFF_1:21;
end;
